source: zzuf/trunk/configure.ac @ 4253

Last change on this file since 4253 was 4248, checked in by Sam Hocevar, 8 years ago

Reorganise FILE structure autoconf tests.

File size: 5.7 KB
Line 
1# $Id: configure.ac 98 2006-09-22 16:27:37Z sam $
2
3AC_INIT(zzuf, 0.12)
4AC_CONFIG_AUX_DIR(.auto)
5AM_CONFIG_HEADER(config.h)
6AM_INIT_AUTOMAKE([no-define tar-ustar])
7
8AC_PREREQ(2.50)
9
10AM_PROG_CC_C_O
11AC_PROG_CPP
12AC_PROG_LIBTOOL
13
14AC_C_INLINE
15AC_C_FUNC
16
17# Library suffix
18AC_MSG_CHECKING(for libzzuf full name)
19case "$shrext_cmds" in
20  "") SONAME="libzzuf.so" ;;
21  *) SONAME="libzzuf$shrext_cmds" ;;
22esac
23AC_MSG_RESULT($SONAME)
24AC_DEFINE_UNQUOTED(SONAME, "$SONAME", [Define to the libzzuf full name])
25
26# Optimizations
27AC_TRY_CFLAGS(-g -O2, CFLAGS="${CFLAGS} -g -O2")
28# Code qui fait des warnings == code de porc == deux baffes dans ta gueule
29AC_TRY_CFLAGS(-Wall, CFLAGS="${CFLAGS} -Wall")
30AC_TRY_CFLAGS(-W, CFLAGS="${CFLAGS} -W")
31AC_TRY_CFLAGS(-Wpointer-arith -Wcast-align -Wcast-qual -Wstrict-prototypes -Wshadow -Waggregate-return -Wmissing-prototypes -Wnested-externs -Wsign-compare, CFLAGS="${CFLAGS} -Wpointer-arith -Wcast-align -Wcast-qual -Wstrict-prototypes -Wshadow -Waggregate-return -Wmissing-prototypes -Wnested-externs -Wsign-compare")
32
33case "${host_os}" in
34  *mingw32*)
35    DLL_LDFLAGS="-Wl,-l,imagehlp" # Trick libtool here
36    WINSOCK2_LIBS="-lws2_32"
37    ac_cv_func_recv=yes
38    ac_cv_func_recvfrom=yes
39    ac_cv_func_socket=yes
40    ac_cv_func_accept=yes
41    ac_cv_func_bind=yes
42    ac_cv_func_connect=yes
43    ;;
44esac
45AC_SUBST(WINSOCK2_LIBS)
46AC_SUBST(DLL_LDFLAGS)
47
48AC_CHECK_HEADERS(windows.h winsock2.h io.h process.h unistd.h inttypes.h stdint.h getopt.h libc.h malloc.h dlfcn.h regex.h sys/cdefs.h sys/socket.h netinet/in.h arpa/inet.h sys/uio.h aio.h sys/mman.h sys/wait.h sys/resource.h sys/time.h endian.h)
49
50AC_CHECK_FUNCS(setenv waitpid setrlimit gettimeofday fork kill pipe _pipe)
51AC_CHECK_FUNCS(open64 __open64 lseek64 __lseek64 mmap64 fopen64 __fopen64 freopen64 __freopen64 dup dup2 ftello ftello64 __ftello64 fseeko fseeko64 __fseeko64 fsetpos64 __fsetpos64 _IO_getc getline getdelim __getdelim fgetln __srefill __filbuf __srget __uflow map_fd memalign posix_memalign aio_read accept bind connect socket readv pread recv recvfrom recvmsg mmap valloc sigaction getpagesize getc_unlocked getchar_unlocked fgetc_unlocked fread_unlocked fgets_unlocked)
52
53AC_CHECK_TYPES(sighandler_t, [], [],
54  [#define _GNU_SOURCE
55   #include <signal.h>])
56AC_CHECK_TYPES(sig_t, [], [],
57  [#include <signal.h>])
58AC_CHECK_TYPES(socklen_t, [], [],
59  [#include <sys/types.h>
60   #include <sys/socket.h>])
61
62AC_MSG_CHECKING(for read() prototype)
63AC_TRY_COMPILE([#define _INCLUDE_POSIX_SOURCE
64                #include <unistd.h>],
65 [ssize_t read(int fd, void *buf, size_t count);],
66 [AC_MSG_RESULT(ssize_t read(... size_t);)
67  AC_DEFINE(READ_USES_SSIZE_T, 1, [Define to 1 if read() uses ssize_t.])],
68 [AC_MSG_RESULT(int read(... unsigned int);)])
69
70AC_MSG_CHECKING(for recv() return value)
71ac_v_recv_t="int"
72AC_TRY_COMPILE([#define _XOPEN_SOURCE_EXTENDED
73                #include <sys/types.h>
74                #include <sys/socket.h>],
75 [ssize_t recv(int s, void *buf, size_t len, int flags);],
76 [ac_v_recv_t="ssize_t"])
77AC_MSG_RESULT($ac_v_recv_t)
78AC_DEFINE_UNQUOTED(RECV_T, $ac_v_recv_t, [Define to the recv() return type])
79
80AC_MSG_CHECKING([for _IO_read_ptr and _IO_read_end in FILE (glibc-style)])
81AC_TRY_COMPILE([#include <stdio.h>],
82 [FILE *fp; fp->_IO_read_ptr++; fp->_IO_read_end++],
83 [ac_cv_have_file_io_read_ptr=yes],
84 [ac_cv_have_file_io_read_ptr=no])
85AC_MSG_RESULT($ac_cv_have_file_io_read_ptr)
86if test "$ac_cv_have_file_io_read_ptr" != "no"; then
87  AC_DEFINE(HAVE_GLIBC_FILE, 1, [Define to 1 if FILE has glibc-style members])
88fi
89
90AC_MSG_CHECKING([for _bf._base, _r and _p in FILE (FreeBSD-style)])
91AC_TRY_COMPILE([#include <stdio.h>],
92 [FILE *fp; fp->_bf._base++; fp->_r++; fp->_p++],
93 [ac_cv_have_file_bf_base=yes],
94 [ac_cv_have_file_bf_base=no])
95AC_MSG_RESULT($ac_cv_have_file_bf_base)
96if test "$ac_cv_have_file_bf_base" != "no"; then
97  AC_DEFINE(HAVE_FREEBSD_FILE, 1, [Define to 1 if FILE has FreeBSD-style members])
98fi
99
100dnl  On HP-UX, fpos64_t == int64_t, but on Linux it's a compound object.
101AC_MSG_CHECKING(how to access fpos64_t x)
102ac_v_fpos64_t="unknown"
103AC_TRY_COMPILE(
104 [#define _LARGEFILE64_SOURCE
105  #include <stdio.h>],
106 [fpos64_t x; long long int y = x.__pos;],
107 [ac_v_fpos64_t="(x).__pos"])
108AC_TRY_COMPILE(
109 [#define _LARGEFILE64_SOURCE
110  #include <stdio.h>],
111 [fpos64_t x; long long int y = (long long int)x;],
112 [ac_v_fpos64_t="(x)"])
113AC_MSG_RESULT($ac_v_fpos64_t)
114AC_DEFINE_UNQUOTED(FPOS_CAST(x), $ac_v_fpos64_t, [Define to a macro for accessing an fpos64_t variable])
115
116AC_MSG_CHECKING(for pragma INIT/FINI)
117AC_TRY_COMPILE([],
118 [#pragma INIT "my_init"
119  void my_init(void)],
120 [AC_MSG_RESULT(yes)
121  AC_DEFINE(HAVE_PRAGMA_INIT, 1, [Define to 1 if you have pragma INIT])],
122 [AC_MSG_RESULT(no)])
123
124AC_MSG_CHECKING(for __printf__ attribute)
125ac_v_attribute_printf=""
126AC_TRY_COMPILE([],
127 [extern void foo(const char *, ...)
128     __attribute__((__format__(__printf__, 1, 2)));],
129 [AC_MSG_RESULT(yes)
130  ac_v_attribute_printf="__attribute__((__format__(__printf__, x, y)))"],
131 [AC_MSG_RESULT(no)])
132AC_DEFINE_UNQUOTED(ATTRIBUTE_PRINTF(x,y), $ac_v_attribute_printf, [Define to the __printf__ attribute if present])
133
134ac_cv_have_getopt_long="no"
135AC_CHECK_FUNCS(getopt_long,
136 [ac_cv_have_getopt_long="yes"],
137 [AC_CHECK_LIB(gnugetopt, getopt_long,
138   [ac_cv_have_getopt_long="yes"
139    GETOPT_LIBS="${GETOPT_LIBS} -lgnugetopt"])])
140if test "$ac_cv_have_getopt_long" != "no"; then
141  AC_DEFINE(HAVE_GETOPT_LONG, 1, Define to 1 if you have the `getopt_long' function.)
142fi
143AM_CONDITIONAL(NEED_GETOPT_LONG, test "$ac_cv_have_getopt_long" = "no")
144AC_SUBST(GETOPT_LIBS)
145
146AC_CHECK_LIB(m, log, [MATH_LIBS="-lm"])
147AC_SUBST(MATH_LIBS)
148AC_CHECK_LIB(dl, dlopen, [DL_LIBS="-ldl"])
149AC_SUBST(DL_LIBS)
150
151AC_CONFIG_FILES([
152  Makefile
153  src/Makefile
154  doc/Makefile
155  test/Makefile
156])
157AC_CONFIG_FILES([
158  doc/zzcat.1
159  doc/zzuf.1
160  doc/libzzuf.3
161])
162AC_OUTPUT
163
Note: See TracBrowser for help on using the repository browser.