source: neercs/trunk/configure.ac @ 4882 Tweet

AC_INIT(neercs, 0.0)

AC_PREREQ(2.50)
AC_CONFIG_SRCDIR(src/main.c)
AC_CONFIG_AUX_DIR(.auto)
AC_CANONICAL_SYSTEM

AM_INIT_AUTOMAKE([subdir-objects no-define tar-ustar silent-rules])

AM_PROG_CC_C_O
AC_PROG_CPP

AC_CANONICAL_HOST

if test "$host_os" == "darwin10.2.0"; then 
    case x${target} in
     x*86*darwin*)
      MACOSX_SDK="${MACOSX_SDK:-/Developer/SDKs/MacOSX10.6.sdk}"
      GCC_VERSION="${GCC_VERSION:-4.0}"
      ARCH="${ARCH:--arch i386}"
      MACOSX_SDK_CFLAGS="${MACOSX_SDK_CFLAGS:--isysroot ${MACOSX_SDK}}"
      MACOSX_SDK_CXXFLAGS="${MACOSX_SDK_CXXFLAGS:-${MACOSX_SDK_CFLAGS}}"
      ;;
    esac
    CC="${CC:-gcc-${GCC_VERSION}}"
    CXX="${CXX:-g++-${GCC_VERSION}}"
    MACOSX_SDK_FRAMEWORKS="${MACOSX_SDK_FRAMEWORKS:--F${MACOSX_SDK}/System/Library/Frameworks}"
    CPPFLAGS="${CPPFLAGS} ${ARCH} ${MACOSX_SDK_FRAMEWORKS}"
    CFLAGS="${CFLAGS} ${MACOSX_SDK_CFLAGS}"
    CXXFLAGS="${CXXFLAGS} ${MACOSX_SDK_CXXFLAGS}"
    OBJCFLAGS="${OBJCFLAGS} ${MACOSX_SDK_CFLAGS}"
    LDFLAGS="${ARCH} ${MACOSX_SDK_LDFLAGS} ${LDFLAGS}"
fi


dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
dnl now otherwise it might be set in an obscure if statement. Same thing for
dnl PKG_PROG_PKG_CONFIG which needs to be called first.
AC_EGREP_CPP(yes, foo)
PKG_PROG_PKG_CONFIG()

dnl Don't let pkg-config fuck our cross-compilation environment
m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
if test "$build" != "$host" -a "${PKG_CONFIG_LIBDIR}" = ""; then
  export PKG_CONFIG_LIBDIR=/dev/null
fi


dnl conditional builds
AC_ARG_ENABLE(debug,
  [  --enable-debug          build debug version of neercs (default no)])
AC_ARG_ENABLE(profiling,
  [  --enable-profiling      build profiling version of neercs (gprof)(default no)])
AC_ARG_ENABLE(python,
  [  --enable-python         build Python interpreter (default yes)])
AS_IF([test "x$enable_python" != "xno"], [
  enable_python="yes"
])
AC_ARG_ENABLE(ruby,
  [  --enable-ruby           build Ruby interpreter (default yes)])
AS_IF([test "x$enable_ruby" != "xno"], [
  enable_ruby="yes"
])

CACA="no"
PKG_CHECK_MODULES(CACA, caca >= 0.99.beta17,
 [CACA="yes"],
 [AC_MSG_RESULT(no)
  AC_MSG_ERROR([you need libcaca version 0.99.beta17 or later])])

AC_CHECK_HEADERS(libutil.h util.h stdio.h pty.h sys/ioctl.h sys/ptrace.h sys/stat.h sys/syscall.h sys/user.h sys/wait.h linux/kdev_t.h linux/major.h security/pam_appl.h security/pam_misc.h pam/pam_appl.h pam/pam_misc.h)

if test "${ac_cv_header_security_pam_misc_h}" = "yes" -o "${ac_cv_header_pam_pam_misc_h}" = "yes"; then
    AC_CHECK_LIB(pam, pam_authenticate,
      [PAM_LIBS="${PAM_LIBS} -lpam"
      AC_DEFINE(USE_LOCK, 1, [Locking the PTY is supported])])
fi
AC_SUBST(PAM_LIBS)

AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
AC_SUBST(MATH_LIBS)

AC_CHECK_LIB(util, forkpty, UTIL_LIBS="${UTIL_LIBS} -lutil")
AC_SUBST(UTIL_LIBS)

AC_MSG_CHECKING(for pty grab support)
case $target in
  i?86-*-linux-*|amd64-*-linux-*|x86_64-*-linux-*)
    AC_DEFINE(USE_GRAB, 1, [Grabbing processes is supported])
    grab=yes ;;
  *)
    grab=no ;;
esac
AC_MSG_RESULT($grab)

if test "${enable_debug}" = "yes"; then
  AC_DEFINE(DEBUG, 1, Define to 1 to activate debug)
fi

AC_DEFINE(_GNU_SOURCE, 1, [Use GNU extentions])

PYTHON="no"
if test "${enable_python}" != "no"; then
PKG_CHECK_MODULES(PYTHON3, python3 >= 3.1,
 [PYTHON="yes"
  PYTHON_CFLAGS="${PYTHON3_CFLAGS}"
  PYTHON_LIBS="${PYTHON3_LIBS}"
  AC_DEFINE(HAVE_PYTHON3, 1, [Define to 1 if Python 3 is present])
  AC_DEFINE(HAVE_PYTHON26, 1, [Define to 1 if Python >= 2.6 is present])],
 [AC_PATH_PROG(PYTHON_CONFIG, python2.6-config, no)
  if test "${PYTHON_CONFIG}" = "no"; then
    AC_PATH_PROG(PYTHON_CONFIG, python2.5-config, no)
  else
    AC_DEFINE(HAVE_PYTHON26, 1, [Define to 1 if Python >= 2.6 is present])
  fi
  if test "${PYTHON_CONFIG}" = "no"; then
    AC_PATH_PROG(PYTHON_CONFIG, python2.4-config, no)
  fi
  if test "${PYTHON_CONFIG}" != "no"; then
    PYTHON="yes"
    PYTHON_CFLAGS="`${PYTHON_CONFIG} --cflags`"
    PYTHON_LIBS="`${PYTHON_CONFIG} --libs`"
    AC_DEFINE(HAVE_PYTHON2, 1, [Define to 1 if Python 2 is present])
  fi])
  if test "${PYTHON}" = "yes"; then
    AC_DEFINE(USE_PYTHON, 1, [Define to 1 to use Python interpreter])
  else
    AC_MSG_RESULT(you need Python 2.4 or later to compile the interpreter)
  fi
fi

AC_SUBST(PYTHON_CFLAGS)
AC_SUBST(PYTHON_LIBS)

# Optimizations / Profiling
CFLAGS="${CFLAGS} -g -O2 -fno-strength-reduce"

if test "${enable_profiling}" = "yes"; then
  CFLAGS="${CFLAGS} -g -O0 -fno-strength-reduce -pg"
else
  CFLAGS="${CFLAGS} -fomit-frame-pointer"
fi

# Code qui fait des warnings == code de porc == deux baffes dans ta gueule
CFLAGS="${CFLAGS} -Wall -Wpointer-arith -Wcast-align -Wcast-qual -Wstrict-prototypes -Wshadow -Waggregate-return -Wmissing-prototypes -Wnested-externs -Wsign-compare"

# Build documentation?
DOXYGEN="no"
LATEX="no"
if test "${enable_doc}" != "no"; then
  AC_PATH_PROG(DOXYGEN, doxygen, no)
  if test "${DOXYGEN}" != "no"; then
    # Build LaTeX documentation?
    AC_PATH_PROG(LATEX, pdflatex, no)
    AC_PATH_PROG(KPSEWHICH, kpsewhich, no)
    AC_PATH_PROG(DVIPS, dvips, no)
    if test "${DVIPS}" = "no" -o "${KPSEWHICH}" = "no"; then
      LATEX="no"
    fi
    if test "${LATEX}" != "no"; then
      AC_MSG_CHECKING(for a4.sty and a4wide.sty)
      if "${KPSEWHICH}" a4.sty >/dev/null 2>&1; then
        if "${KPSEWHICH}" a4wide.sty >/dev/null 2>&1; then
          AC_MSG_RESULT(yes)
        else
          LATEX="no"
          AC_MSG_RESULT(no)
        fi
      else
        LATEX="no"
        AC_MSG_RESULT(no)
      fi
    fi
  fi
fi
AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")

AM_CONFIG_HEADER(config.h)
AC_CONFIG_FILES([
  Makefile
  doc/Makefile
  src/Makefile
  data/Makefile
  test/Makefile
])
AC_CONFIG_FILES([
  doc/doxygen.cfg
])
AC_OUTPUT