source: libpipi/trunk/configure.ac @ 3622

Last change on this file since 3622 was 3622, checked in by Sam Hocevar, 11 years ago

Do not bail out if only GDI+ is found.

File size: 8.5 KB
Line 
1# $Id$
2
3AC_INIT(libpipi, 0.0)
4AC_PREREQ(2.50)
5AC_CONFIG_AUX_DIR(.auto)
6AC_CANONICAL_SYSTEM
7AM_INIT_AUTOMAKE([no-define tar-ustar])
8dnl AM_MAINTAINER_MODE
9
10AM_CONFIG_HEADER(config.h)
11
12LT_MAJOR="0"
13LT_MINOR="0"
14LT_MICRO="0"
15AC_SUBST(LT_MAJOR)
16AC_SUBST(LT_MINOR)
17AC_SUBST(LT_MICRO)
18LT_VERSION="$LT_MAJOR:$LT_MINOR:$LT_MICRO"
19AC_SUBST(LT_VERSION)
20
21AM_PROG_CC_C_O
22AC_PROG_CPP
23AC_PROG_CXX
24AC_PROG_CXXCPP
25AC_PROG_OBJC
26_AM_DEPENDENCIES([OBJC])
27OBJC="${CC}"
28AC_SUBST(OBJC)
29AC_SUBST(OBJCFLAGS)
30
31AC_LIBTOOL_WIN32_DLL
32AM_PROG_LIBTOOL
33AC_LIBTOOL_CXX
34
35AC_C_CONST
36AC_C_INLINE
37
38dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
39dnl now otherwise it might be set in an obscure if statement. Same thing for
40dnl PKG_PROG_PKG_CONFIG which needs to be called first.
41AC_EGREP_CPP(yes, foo)
42PKG_PROG_PKG_CONFIG()
43m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
44if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
45  export PKG_CONFIG_LIBDIR=/dev/null
46fi
47
48AC_MSG_CHECKING(for library suffix)
49LT_SUFFIX="`./libtool -n --tag CC --mode=link gcc -o libTEST.la -no-undefined -version-number 123:666:999 -rpath / | xargs -n 1 | sed -ne 's/.*libTEST\(@<:@^, ()0-9@:>@*\)123\(@<:@^, ()0-9@:>@*\).*/\1'$LT_MAJOR'\2/p' | grep -v '\.$' | head -n 1`"
50if test "$LT_SUFFIX" = ""; then
51  LT_SUFFIX=".so.$LT_MAJOR"
52  AC_MSG_RESULT([unknown, defaulting to $LT_SUFFIX])
53else
54  AC_MSG_RESULT($LT_SUFFIX)
55fi
56AC_SUBST(LT_SUFFIX)
57
58dnl language bindings
59AC_ARG_ENABLE(csharp,
60  [  --enable-csharp         C# bindings (autodetected)])
61
62dnl conditional builds
63AC_ARG_ENABLE(debug,
64  [  --enable-debug          build debug versions of the library (default no)])
65AC_ARG_ENABLE(tiles,
66  [  --enable-tiles          experimental tiles support (default no)])
67
68AC_CHECK_HEADERS(stdio.h stdarg.h inttypes.h endian.h stdint.h getopt.h)
69
70ac_cv_have_getopt_long="no"
71AC_CHECK_FUNCS(getopt_long,
72 [ac_cv_have_getopt_long="yes"],
73 [AC_CHECK_LIB(gnugetopt, getopt_long,
74   [ac_cv_have_getopt_long="yes"
75    GETOPT_LIBS="${GETOPT_LIBS} -lgnugetopt"])])
76if test "$ac_cv_have_getopt_long" != "no"; then
77  AC_DEFINE(HAVE_GETOPT_LONG, 1, Define to 1 if you have the ‘getopt_long’ function.)
78fi
79AM_CONDITIONAL(NEED_GETOPT_LONG, test "$ac_cv_have_getopt_long" = "no")
80AC_SUBST(GETOPT_LIBS)
81
82# How to get the C99 types. See pipi/pipi_types.h.in for details about
83# the PIPI_TYPES variable
84if test "${ac_cv_my_have_vga}" = "yes"; then
85  PIPI_TYPES=0
86else
87  AC_CHECK_HEADERS(stdint.h,
88    [PIPI_TYPES=1],
89    [AC_CHECK_HEADERS(inttypes.h,
90      [PIPI_TYPES=2],
91      [AC_CHECK_HEADERS(windows.h,
92        [PIPI_TYPES=3],
93        [PIPI_TYPES=0])])])
94fi
95AC_SUBST(PIPI_TYPES)
96
97# Optimizations
98CFLAGS="${CFLAGS} -g -O2 -fno-strength-reduce -fomit-frame-pointer"
99# Code qui fait des warnings == code de porc == deux baffes dans ta gueule
100CFLAGS="${CFLAGS} -Wall -Wextra -Wpointer-arith -Wcast-align -Wcast-qual -Wstrict-prototypes -Wshadow -Waggregate-return -Wmissing-prototypes -Wnested-externs -Wsign-compare"
101CXXFLAGS="${CXXFLAGS} -Wall -Wextra -Wpointer-arith -Wcast-align -Wcast-qual -Wshadow -Wsign-compare"
102
103AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
104
105# Use SDL?
106ac_cv_my_have_sdl="no"
107save_CPPFLAGS="${CPPFLAGS}"
108AC_PATH_PROG(SDL_CONFIG, sdl-config, no)
109if test "${SDL_CONFIG}" != "no"; then
110  CPPFLAGS="${CPPFLAGS} `sdl-config --cflags`"
111fi
112AC_CHECK_HEADERS(SDL_image.h,
113 [ac_cv_my_have_sdl="yes"],
114 [ac_cv_my_have_sdl="no"])
115CPPFLAGS="${save_CPPFLAGS}"
116if test "${ac_cv_my_have_sdl}" != "no"; then
117  AC_DEFINE(USE_SDL, 1, Define to 1 to use SDL_image)
118fi
119AM_CONDITIONAL(USE_SDL, test "${ac_cv_my_have_sdl}" = "yes")
120
121# Use OpenCV?
122ac_cv_my_have_opencv="no"
123OPENCV="no"
124PKG_CHECK_MODULES(OPENCV, opencv, [ac_cv_my_have_opencv="yes"], [:])
125if test "${ac_cv_my_have_opencv}" != "no"; then
126  AC_DEFINE(USE_OPENCV, 1, Define to 1 to use OpenCV)
127fi
128AM_CONDITIONAL(USE_OPENCV, test "${ac_cv_my_have_opencv}" = "yes")
129
130# Use Imlib2?
131ac_cv_my_have_imlib2="no"
132IMLIB2="no"
133PKG_CHECK_MODULES(IMLIB2, imlib2, [ac_cv_my_have_imlib2="yes"], [:])
134if test "${ac_cv_my_have_imlib2}" != "no"; then
135  AC_DEFINE(USE_IMLIB2, 1, Define to 1 to use Imlib2)
136fi
137AM_CONDITIONAL(USE_IMLIB2, test "${ac_cv_my_have_imlib2}" = "yes")
138
139# Use Windows GDI?
140ac_cv_my_have_gdi="no"
141GDI="no"
142AC_CHECK_HEADERS(windows.h,
143 [ac_cv_my_have_gdi="yes"],
144 [ac_cv_my_have_gdi="no"])
145if test "${ac_cv_my_have_gdi}" != "no"; then
146  AC_DEFINE(USE_GDI, 1, Define to 1 to use GDI)
147fi
148AM_CONDITIONAL(USE_GDI, test "${ac_cv_my_have_gdi}" = "yes")
149
150# Use Windows GDI+?
151ac_cv_my_have_gdiplus="no"
152AC_LANG_PUSH(C++)
153AC_CHECK_HEADERS(Gdiplus.h,
154 [ac_cv_my_have_gdiplus="yes"],
155 [ac_cv_my_have_gdiplus="no"],
156 [#include <windows.h>])
157AC_LANG_POP(C++)
158if test "${ac_cv_my_have_gdiplus}" != "no"; then
159  AC_DEFINE(USE_GDIPLUS, 1, Define to 1 to use GDI+)
160fi
161AM_CONDITIONAL(USE_GDIPLUS, test "${ac_cv_my_have_gdiplus}" = "yes")
162
163# Use Cocoa?
164ac_cv_my_have_cocoa="no"
165AC_CHECK_HEADERS(/System/Library/Frameworks/Cocoa.framework/Headers/Cocoa.h,
166[
167 MACOSX_SDK_FRAMEWORKS="-F${MACOSX_SDK}/System/Library/Frameworks"
168 CPPFLAGS="${CPPFLAGS} ${ARCH} ${MACOSX_SDK_FRAMEWORKS} -I/Developer//SDKs/MacOSX10.5.sdk/System/Library/Frameworks/QuartzCore.framework/Versions/A/Headers/"
169 CFLAGS="${CFLAGS} ${MACOSX_SDK_CFLAGS} -I/Developer//SDKs/MacOSX10.5.sdk/System/Library/Frameworks/QuartzCore.framework/Versions/A/Headers/"
170 CXXFLAGS="${CXXFLAGS} ${MACOSX_SDK_CXXFLAGS}"
171 OBJCFLAGS="${OBJCFLAGS} ${MACOSX_SDK_CFLAGS}"
172 LDFLAGS="${ARCH} ${MACOSX_SDK_LDFLAGS} ${LDFLAGS}"
173 AC_DEFINE(USE_COCOA, 1, Define to 1 to activate the Cocoa backend driver)
174#    CACA_LIBS="${CACA_LIBS} -Wl,-syslibroot,${MACOSX_SDK},-framework,Cocoa"
175#    CACA_DRIVERS="${CACA_DRIVERS} cocoa"
176 ac_cv_my_have_cocoa="yes"],
177 [ac_cv_my_have_cocoa="no"]
178 )
179AM_CONDITIONAL(USE_COCOA, test "${ac_cv_my_have_cocoa}" = "yes")
180
181# Use libjpeg?
182ac_cv_my_have_jpeg="no"
183AC_CHECK_HEADERS(jpeglib.h,
184 [ac_cv_my_have_jpeg="yes"],
185 [ac_cv_my_have_jpeg="no"])
186if test "${ac_cv_my_have_jpeg}" != "no"; then
187  AC_DEFINE(USE_JPEG, 1, Define to 1 to use libjpeg)
188fi
189AM_CONDITIONAL(USE_JPEG, test "${ac_cv_my_have_jpeg}" = "yes")
190
191if test "${ac_cv_my_have_sdl}" = "no" -a "${ac_cv_my_have_imlib2}" = "no" -a "${ac_cv_my_have_opencv}" = "no" -a "${ac_cv_my_have_cocoa}" = "no" -a "${ac_cv_my_have_jpeg}" = "no" -a "${ac_cv_my_have_gdiplus}" = "no"; then
192  AC_MSG_ERROR([[cannot find GDI+, SDL_Image, Imlib2, Cocoa or OpenCV, please install one of them]])
193fi
194
195if test "${enable_debug}" = "yes"; then
196  AC_DEFINE(DEBUG, 1, Define to 1 to activate debug)
197fi
198
199if test "${enable_tiles}" = "yes"; then
200  AC_DEFINE(USE_TILES, 1, Define to 1 to activate experimental tiles)
201fi
202
203AC_SUBST(MATH_LIBS)
204
205# Build the .NET bindings?
206ac_cv_my_have_csharp="no"
207if test "${enable_csharp}" != "no"; then
208  AC_PATH_PROG(GMCS, gmcs, no)
209  AC_PATH_PROG(GACUTIL, gacutil, no)
210  if test "${GMCS}" != "no" -a "${GACUTIL}" != "no"; then
211    ac_cv_my_have_csharp="yes"
212  fi
213fi
214AM_CONDITIONAL(USE_CSHARP, test "${ac_cv_my_have_csharp}" = "yes")
215
216# Build the movie thumbnailer?
217ac_cv_my_have_ffmpeg="yes"
218PKG_CHECK_MODULES([LIBAVCODEC], [libavcodec-uninstalled], [:], [ac_cv_my_have_ffmpeg=no])
219PKG_CHECK_MODULES([LIBAVFORMAT], [libavformat-uninstalled], [:], [ac_cv_my_have_ffmpeg=no])
220PKG_CHECK_MODULES([LIBSWSCALE], [libswscale-uninstalled], [:], [ac_cv_my_have_ffmpeg=no])
221if test "${ac_cv_my_have_ffmpeg}" = "no"; then
222  ac_cv_my_have_ffmpeg="yes"
223  PKG_CHECK_MODULES([LIBAVCODEC], [libavcodec], [:], [ac_cv_my_have_ffmpeg=no])
224  PKG_CHECK_MODULES([LIBAVFORMAT], [libavformat], [:], [ac_cv_my_have_ffmpeg=no])
225  PKG_CHECK_MODULES([LIBSWSCALE], [libswscale], [:], [ac_cv_my_have_ffmpeg=no])
226fi
227AM_CONDITIONAL(USE_FFMPEG, test "${ac_cv_my_have_ffmpeg}" = "yes")
228
229# Build CGAL stuff?
230ac_cv_my_have_cgal="no"
231AC_LANG_PUSH(C++)
232AC_CHECK_HEADERS(CGAL/version.h,
233 [ac_cv_my_have_cgal="yes"],
234 [ac_cv_my_have_cgal="no"])
235AC_LANG_POP(C++)
236if test "${ac_cv_my_have_cgal}" != "no"; then
237  AC_DEFINE(USE_CGAL, 1, Define to 1 to use CGAL)
238fi
239AM_CONDITIONAL(USE_CGAL, test "${ac_cv_my_have_cgal}" = "yes")
240
241# Build The Pimp?
242ac_cv_my_have_gtksharp="${ac_cv_my_have_csharp}"
243PKG_CHECK_MODULES([GLIB_SHARP_20], [glib-sharp-2.0], [:], [ac_cv_my_have_gtksharp=no])
244PKG_CHECK_MODULES([GTK_SHARP_20], [gtk-sharp-2.0], [:], [ac_cv_my_have_gtksharp=no])
245AM_CONDITIONAL(USE_GTKSHARP, test "${ac_cv_my_have_gtksharp}" != no)
246
247AC_CONFIG_FILES([
248  Makefile
249  pipi/Makefile
250  src/Makefile
251  genethumb/Makefile
252  examples/Makefile
253  test/Makefile
254  pipi-sharp/Makefile
255  ThePimp/Makefile
256  win32/Makefile
257])
258AC_CONFIG_FILES([
259  pipi/pipi_types.h
260  pipi/pipi.pc
261  pipi-sharp/pipi-sharp.pc
262  pipi-sharp/pipi-sharp.dll.config
263])
264AC_CONFIG_FILES([ThePimp/pimp], [chmod +x ThePimp/pimp])
265
266AC_OUTPUT
267
Note: See TracBrowser for help on using the repository browser.