source: libcaca/trunk/configure.ac @ 861

Last change on this file since 861 was 861, checked in by Sam Hocevar, 14 years ago
  • Look for htons/htonl in netinet/in.h in addition to arpa/inet.h
  • Implement htons/htonl in common.h just in case.
  • Property svn:keywords set to Id
File size: 10.5 KB
Line 
1# $Id: configure.ac 861 2006-04-24 20:45:55Z sam $
2
3AC_INIT(caca/caca.c)
4
5AC_PREREQ(2.50)
6AC_CONFIG_AUX_DIR(autotools)
7AC_CANONICAL_SYSTEM
8
9AM_INIT_AUTOMAKE(libcaca, 0.99.beta1)
10LT_VERSION="99:0:99"
11AC_SUBST(LT_VERSION)
12AM_CONFIG_HEADER(config.h)
13
14AM_PROG_CC_C_O
15AC_PROG_CPP
16AC_PROG_CXX
17AC_PROG_CXXCPP
18AM_PROG_AS
19
20AC_LIBTOOL_WIN32_DLL
21AM_PROG_LIBTOOL
22AC_LIBTOOL_CXX
23
24AC_C_CONST
25AC_C_INLINE
26AC_TYPE_SIGNAL
27
28dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
29dnl now otherwise it might be set in an obscure if statement. Same thing for
30dnl PKG_PROG_PKG_CONFIG which needs to be called first.
31AC_EGREP_CPP(yes, foo)
32PKG_PROG_PKG_CONFIG()
33
34dnl output driver features
35AC_ARG_ENABLE(slang,
36  [  --enable-slang          slang graphics support (autodetected)])
37AC_ARG_ENABLE(ncurses,
38  [  --enable-ncurses        ncurses graphics support (autodetected)])
39AC_ARG_ENABLE(win32,
40  [  --enable-win32          Windows console support (autodetected)])
41AC_ARG_ENABLE(conio,
42  [  --enable-conio          DOS conio.h graphics support (autodetected)])
43AC_ARG_ENABLE(x11,
44  [  --enable-x11            X11 support (autodetected)])
45AC_ARG_ENABLE(gl,
46  [  --enable-gl             OpenGL support (autodetected)])
47AC_ARG_ENABLE(network,
48  [  --enable-network        Network support (autodetected)])
49AC_ARG_ENABLE(vga,
50  [  --enable-vga            VGA support (default disabled)])
51
52dnl language bindings
53AC_ARG_ENABLE(cpp,
54  [  --enable-cpp            C++ bindings (default disabled)])
55
56dnl example programs features
57AC_ARG_ENABLE(imlib2,
58  [  --enable-imlib2         Imlib2 graphics support (default enabled)])
59
60dnl conditional builds
61AC_ARG_ENABLE(doc,
62  [  --enable-doc            build documentation (needs doxygen and LaTeX)])
63
64AC_CHECK_HEADERS(stdio.h stdarg.h signal.h sys/ioctl.h sys/time.h inttypes.h endian.h unistd.h arpa/inet.h netinet/in.h)
65AC_CHECK_FUNCS(signal ioctl vsnprintf getenv putenv strcasecmp htons)
66AC_CHECK_FUNCS(usleep gettimeofday)
67
68AC_MSG_CHECKING(for Sleep)
69AC_TRY_COMPILE([#include <windows.h>],[Sleep(42);],
70 [AC_MSG_RESULT(yes)
71  AC_DEFINE(HAVE_SLEEP, 1, [Define to 1 if you have the `Sleep' function.])],
72 [AC_MSG_RESULT(no)])
73
74AC_MSG_CHECKING(for fsin/fcos)
75AC_TRY_COMPILE([],[asm("fsin\n\tfcos");],
76 [AC_MSG_RESULT(yes)
77  AC_DEFINE(HAVE_FSIN_FCOS, 1, [Define to 1 if you have the `fsin' and `fcos' operands.])],
78 [AC_MSG_RESULT(no)])
79
80AC_MSG_CHECKING(for fldln2/fxch/fyl2x)
81AC_TRY_COMPILE([],[asm("fldln2; fldln2; fxch; fyl2x");],
82 [AC_MSG_RESULT(yes)
83  AC_DEFINE(HAVE_FLDLN2, 1, [Define to 1 if you have the `fldln2' and other floating points operands.])],
84 [AC_MSG_RESULT(no)])
85
86AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
87
88CACA_DRIVERS=""
89
90if test "${enable_conio}" != "no"; then
91  ac_cv_my_have_conio="no"
92  AC_CHECK_HEADERS(conio.h,
93   [AC_MSG_CHECKING(for ScreenUpdate in pc.h)
94    AC_EGREP_HEADER(ScreenUpdate, pc.h,
95     [ac_cv_my_have_conio="yes"
96      AC_MSG_RESULT(yes)
97      AC_DEFINE(SCREENUPDATE_IN_PC_H, 1,
98                Define to 1 if <pc.h> defines ScreenUpdate.)
99      AC_DEFINE(USE_CONIO, 1, Define to 1 to activate the conio.h backend driver)
100      CACA_DRIVERS="${CACA_DRIVERS} conio"],
101     [AC_MSG_RESULT(no)])])
102  if test "${ac_cv_my_have_conio}" = "no" -a "${enable_conio}" = "yes"; then
103    AC_MSG_ERROR([cannot find conio.h])
104  fi
105fi
106
107if test "${enable_win32}" != "no"; then
108  ac_cv_my_have_win32="no"
109  AC_CHECK_HEADERS(windows.h,
110   [AC_MSG_CHECKING(for AllocConsole in windows.h)
111    AC_EGREP_HEADER(AllocConsole, windows.h,
112     [ac_cv_my_have_win32="yes"
113      AC_MSG_RESULT(yes)
114      AC_DEFINE(ALLOCCONSOLE_IN_WINDOWS_H, 1,
115                Define to 1 if <windows.h> defines AllocConsole.)
116      AC_DEFINE(USE_WIN32, 1, Define to 1 to activate the win32 backend driver)
117      CACA_DRIVERS="${CACA_DRIVERS} win32"],
118     [AC_MSG_RESULT(no)])])
119  if test "${ac_cv_my_have_win32}" = "no" -a "${enable_win32}" = "yes"; then
120    AC_MSG_ERROR([cannot find win32 console development files])
121  fi
122fi
123
124if test "${enable_slang}" != "no"; then
125  ac_cv_my_have_slang="no"
126  AC_CHECK_HEADERS(slang.h slang/slang.h,
127   [ac_cv_my_have_slang="yes"
128    AC_DEFINE(USE_SLANG, 1, Define to 1 to activate the slang backend driver)
129    AC_CHECK_LIB(slang, SLsmg_utf8_enable,
130     [AC_DEFINE(HAVE_SLSMG_UTF8_ENABLE, 1, Define to 1 if you have the `SLsmg_utf8_enable' function.)])
131    CPPFLAGS="${CPPFLAGS} -DOPTIMISE_SLANG_PALETTE=1"
132    CACA_LIBS="${CACA_LIBS} -lslang"
133    CACA_DRIVERS="${CACA_DRIVERS} slang"
134    break])
135  if test "${ac_cv_my_have_slang}" = "no" -a "${enable_slang}" = "yes"; then
136    AC_MSG_ERROR([cannot find slang development files])
137  fi
138fi
139
140if test "${enable_x11}" != "no"; then
141  AC_PATH_X
142  AC_CHECK_LIB(X11, XOpenDisplay,
143   [ac_cv_my_have_x11="yes"
144    if test -n "${x_includes}"; then X_CFLAGS="-I${x_includes}"; fi
145    if test -n "${x_libraries}"; then X_LIBS="-lX11 -L${x_libraries}"; fi
146    AC_DEFINE(USE_X11, 1, Define to 1 to activate the X11 backend driver)
147    CPPFLAGS="${CPPFLAGS} ${X_CFLAGS}"
148    CACA_LIBS="${CACA_LIBS} ${X_LIBS}"
149    CACA_DRIVERS="${CACA_DRIVERS} x11"],
150   [ac_cv_my_have_x11="no"],
151   [[-lXt `if test -n "${x_libraries}"; then echo -L${x_libraries}; fi`]])
152  AC_CHECK_HEADERS(X11/XKBlib.h)
153  if test "${ac_cv_my_have_x11}" != "yes" -a "${enable_x11}" = "yes"; then
154    AC_MSG_ERROR([cannot find X11 development files])
155  fi
156fi
157
158if test "${enable_gl}" != "no"; then
159  ac_cv_my_have_gl="no"
160  AC_CHECK_HEADERS(GL/gl.h OpenGL/gl.h,
161   [AC_CHECK_HEADERS(GL/glut.h,
162     [AC_CHECK_LIB(glut, glutCloseFunc,
163       [AC_DEFINE(HAVE_GLUTCLOSEFUNC, 1, Define to 1 if you have the `glutCloseFunc' function.)])
164      AC_CHECK_LIB(glut, glutMainLoopEvent,
165       [ac_cv_my_have_gl="yes"])
166      AC_CHECK_LIB(glut, glutCheckLoop,
167       [ac_cv_my_have_gl="yes"
168        AC_DEFINE(HAVE_GLUTCHECKLOOP, 1, Define to 1 if you have the `glutCheckLoop' function.)])])
169      break])
170  if test "${ac_cv_my_have_gl}" = "yes"; then
171    AC_DEFINE(USE_GL, 1, Define to 1 to activate the OpenGL backend driver)
172    CACA_LIBS="${CACA_LIBS} -lGL -lglut"
173    CACA_DRIVERS="${CACA_DRIVERS} gl"
174  elif test "${enable_gl}" = "yes"; then
175    AC_MSG_ERROR([cannot find OpenGL+FreeGLUT development files])
176  fi
177fi
178
179if test "${enable_network}" != "no"; then
180  ac_cv_my_have_network="no"
181  AC_CHECK_HEADERS(sys/socket.h,
182     [ac_cv_my_have_network="yes"
183      AC_DEFINE(USE_NETWORK, 1, Define to 1 to activate the network backend driver)
184      CACA_DRIVERS="${CACA_DRIVERS} network"])
185  if test "${ac_cv_my_have_network}" = "no" -a "${enable_network}" = "yes"; then
186    AC_MSG_ERROR([cannot find standard networking socket files])
187  fi
188fi
189
190if test "${enable_ncurses}" != "no"; then
191  ac_cv_my_have_ncurses="no"
192  AC_CHECK_HEADERS(ncursesw/ncurses.h ncurses/ncurses.h ncurses.h curses.h,
193   [ncurses="no"
194    AC_CHECK_LIB(ncursesw, initscr,
195     [ncurses="-lncursesw"],
196     [AC_CHECK_LIB(ncurses, initscr,
197       [ncurses="-lncurses"])])
198    if test "${ncurses}" = "no"; then
199      continue
200    fi
201    ac_cv_my_have_ncurses="yes"
202    AC_DEFINE(USE_NCURSES, 1, Define to 1 to activate the ncurses backend driver)
203    CACA_LIBS="${CACA_LIBS} ${ncurses}"
204    CACA_DRIVERS="${CACA_DRIVERS} ncurses"
205    dnl  Check for resizeterm or resize_term
206    SAVED_LIBS="${LIBS}"
207    LIBS="${LIBS} ${ncurses}"
208    AC_CHECK_FUNCS(resizeterm resize_term)
209    LIBS="${SAVED_LIBS}"
210    break])
211  if test "${ac_cv_my_have_ncurses}" = "no" -a "${enable_ncurses}" = "yes"; then
212    AC_MSG_ERROR([cannot find ncurses development files])
213  fi
214fi
215
216if test "${enable_vga}" = "yes"; then
217  ac_cv_my_have_vga="yes"
218  CPPFLAGS="${CPPFLAGS} -I. -D__KERNEL__ -nostdinc -include kernel/kernel.h"
219  CFLAGS="${CFLAGS} -fno-builtin -O2 -Wall"
220  CCASFLAGS="${CCASFLAGS} -I."
221  LDFLAGS="${LDFLAGS} -nostdlib -Wl,-N -Wl,-Ttext -Wl,100000"
222  AC_DEFINE(USE_VGA, 1, Define to 1 to activate the VGA backend driver)
223  CACA_DRIVERS="${CACA_DRIVERS} vga"
224fi
225AM_CONDITIONAL(USE_KERNEL, test "${ac_cv_my_have_vga}" = "yes")
226
227AC_MSG_CHECKING(valid output drivers)
228if test -z "${CACA_DRIVERS}"; then
229  AC_MSG_RESULT(no)
230  AC_MSG_ERROR([no output drivers were selected!])
231else
232  AC_MSG_RESULT([${CACA_DRIVERS}])
233fi
234
235AC_SUBST(MATH_LIBS)
236AC_SUBST(CACA_LIBS)
237
238# Optimizations
239CFLAGS="${CFLAGS} -g -O2 -fno-strength-reduce -fomit-frame-pointer"
240# Code qui fait des warnings == code de porc == deux baffes dans ta gueule
241# [Jylam] Removed -Wshadow in order to avoid ncurses/gl conflict
242# (Comme quoi on est pas les seuls porcs)
243CFLAGS="${CFLAGS} -Wall -Wpointer-arith -Wcast-align -Wcast-qual -Wstrict-prototypes -Waggregate-return -Wmissing-prototypes -Wnested-externs -Wsign-compare"
244
245# Build the C++ bindings?
246ac_cv_my_have_cpp="no"
247if test "${enable_cpp}" = "yes"; then
248  ac_cv_my_have_cpp="yes"
249fi
250AM_CONDITIONAL(USE_CPP, test "${ac_cv_my_have_cpp}" = "yes")
251
252# Use Imlib2?
253ac_cv_my_have_imlib2="no"
254save_CPPFLAGS="${CPPFLAGS}"
255if test "${enable_imlib2}" != "no"; then
256  AC_PATH_PROG(IMLIB2_CONFIG, imlib2-config, no)
257  if test "${IMLIB2_CONFIG}" != "no"; then
258    CPPFLAGS="${CPPFLAGS} `imlib2-config --cflags` -DX_DISPLAY_MISSING=1"
259  fi
260  AC_CHECK_HEADERS(Imlib2.h,
261    ac_cv_my_have_imlib2="yes",
262   [ac_cv_my_have_imlib2="no"
263    AC_MSG_ERROR([[cannot find Imlib2 development files. Without Imlib2, cacaview will only open BMP files; if this is really what you want, re-run configure with '--disable-imlib2'.]])])
264  CPPFLAGS="${save_CPPFLAGS}"
265fi
266AM_CONDITIONAL(USE_IMLIB2, test "${ac_cv_my_have_imlib2}" = "yes")
267
268# Build development tools?
269PANGOFT2="no"
270PKG_CHECK_MODULES(pangoft2, pangoft2, [PANGOFT2="yes"], [AC_MSG_RESULT(no)])
271AM_CONDITIONAL(USE_PANGO, test "${PANGOFT2}" != "no")
272
273# Build documentation?
274DOXYGEN="no"
275LATEX="no"
276if test "${enable_doc}" != "no"; then
277  AC_PATH_PROG(DOXYGEN, doxygen, no)
278  if test "${DOXYGEN}" = "no"; then
279    AC_MSG_ERROR([[cannot find doxygen, which is needed to build the libcaca documentation; if this is really what you want, re-run configure with '--disable-doc'.]])
280  fi
281
282  # Build LaTeX documentation?
283  AC_PATH_PROG(LATEX, pdflatex, no)
284  AC_PATH_PROG(DVIPS, dvips, no)
285  if test "${DVIPS}" = "no"; then
286    LATEX="no"
287  fi
288  AC_MSG_CHECKING(for a4wide.sty)
289  if test -f /usr/share/texmf/tex/latex/misc/a4wide.sty; then
290    AC_MSG_RESULT(yes)
291  elif test -f /usr/share/texmf-tetex/tex/latex/a4wide/a4wide.sty; then
292    AC_MSG_RESULT(yes)
293  else
294    LATEX="no"
295    AC_MSG_RESULT(no)
296  fi
297fi
298AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
299AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")
300
301AC_CONFIG_FILES([
302  Makefile
303  kernel/Makefile
304  cucul/Makefile
305  caca/Makefile
306  src/Makefile
307  test/Makefile
308  tools/Makefile
309  cpp/Makefile
310  doc/Makefile
311  autotools/Makefile
312  debian/Makefile
313  msvc/Makefile
314])
315AC_CONFIG_FILES([
316  cucul/cucul.pc
317  caca/caca.pc
318  doc/doxygen.cfg
319])
320AC_CONFIG_FILES([caca-config], [chmod 0755 caca-config])
321AC_OUTPUT
322
Note: See TracBrowser for help on using the repository browser.