source: libcaca/trunk/configure.ac @ 629

Last change on this file since 629 was 629, checked in by Sam Hocevar, 14 years ago
  • Use UTF-8 enable ncurses (ncursesw) if available. Doesn't seem to work.
  • Property svn:keywords set to Id
File size: 9.2 KB
Line 
1# $Id: configure.ac 629 2006-03-16 12:49:20Z sam $
2
3AC_INIT(caca/caca.c)
4
5AC_PREREQ(2.50)
6AC_CONFIG_AUX_DIR(autotools)
7AC_CANONICAL_SYSTEM
8
9AM_INIT_AUTOMAKE(libcaca, 0.10)
10AM_CONFIG_HEADER(config.h)
11
12AM_PROG_CC_C_O
13AC_PROG_CPP
14AM_PROG_AS
15
16AC_LIBTOOL_WIN32_DLL
17AM_PROG_LIBTOOL
18
19AC_C_CONST
20AC_C_INLINE
21AC_TYPE_SIGNAL
22
23dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
24dnl now otherwise it might be set in an obscure if statement.
25AC_EGREP_CPP(foo, foo)
26
27dnl output driver features
28AC_ARG_ENABLE(slang,
29  [  --enable-slang          slang graphics support (autodetected)])
30AC_ARG_ENABLE(ncurses,
31  [  --enable-ncurses        ncurses graphics support (autodetected)])
32AC_ARG_ENABLE(win32,
33  [  --enable-win32          Windows console support (autodetected)])
34AC_ARG_ENABLE(conio,
35  [  --enable-conio          DOS conio.h graphics support (autodetected)])
36AC_ARG_ENABLE(x11,
37  [  --enable-x11            X11 support (autodetected)])
38AC_ARG_ENABLE(gl,
39  [  --enable-gl             OpenGL support (autodetected)])
40AC_ARG_ENABLE(network,
41  [  --enable-network        Network support (autodetected)])
42AC_ARG_ENABLE(vga,
43  [  --enable-vga            VGA support (default disabled)])
44
45dnl example programs features
46AC_ARG_ENABLE(imlib2,
47  [  --enable-imlib2         Imlib2 graphics support (default enabled)])
48
49dnl conditional builds
50AC_ARG_ENABLE(doc,
51  [  --enable-doc            build documentation (needs doxygen and LaTeX)])
52
53AC_CHECK_HEADERS(stdio.h stdarg.h signal.h sys/ioctl.h sys/time.h inttypes.h endian.h unistd.h)
54AC_CHECK_FUNCS(signal ioctl vsnprintf getenv putenv strcasecmp)
55AC_CHECK_FUNCS(usleep gettimeofday)
56
57AC_MSG_CHECKING(for Sleep)
58AC_TRY_COMPILE([#include <windows.h>],[Sleep(42);],
59 [AC_MSG_RESULT(yes)
60  AC_DEFINE(HAVE_SLEEP, 1, [Define to 1 if you have the `Sleep' function.])],
61 [AC_MSG_RESULT(no)])
62AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
63
64CACA_DRIVERS=""
65
66if test "${enable_conio}" != "no"; then
67  ac_cv_my_have_conio="no"
68  AC_CHECK_HEADERS(conio.h,
69   [AC_MSG_CHECKING(for ScreenUpdate in pc.h)
70    AC_EGREP_HEADER(ScreenUpdate, pc.h,
71     [ac_cv_my_have_conio="yes"
72      AC_MSG_RESULT(yes)
73      AC_DEFINE(SCREENUPDATE_IN_PC_H, 1,
74                Define to 1 if <pc.h> defines ScreenUpdate.)
75      AC_DEFINE(USE_CONIO, 1, Define to 1 to activate the conio.h backend driver)
76      CACA_DRIVERS="${CACA_DRIVERS} conio"],
77     [AC_MSG_RESULT(no)])])
78  if test "${ac_cv_my_have_conio}" = "no" -a "${enable_conio}" = "yes"; then
79    AC_MSG_ERROR([cannot find conio.h])
80  fi
81fi
82
83if test "${enable_win32}" != "no"; then
84  ac_cv_my_have_win32="no"
85  AC_CHECK_HEADERS(windows.h,
86   [AC_MSG_CHECKING(for AllocConsole in windows.h)
87    AC_EGREP_HEADER(AllocConsole, windows.h,
88     [ac_cv_my_have_win32="yes"
89      AC_MSG_RESULT(yes)
90      AC_DEFINE(ALLOCCONSOLE_IN_WINDOWS_H, 1,
91                Define to 1 if <windows.h> defines AllocConsole.)
92      AC_DEFINE(USE_WIN32, 1, Define to 1 to activate the win32 backend driver)
93      CACA_DRIVERS="${CACA_DRIVERS} win32"],
94     [AC_MSG_RESULT(no)])])
95  if test "${ac_cv_my_have_win32}" = "no" -a "${enable_win32}" = "yes"; then
96    AC_MSG_ERROR([cannot find win32 console development files])
97  fi
98fi
99
100if test "${enable_slang}" != "no"; then
101  ac_cv_my_have_slang="no"
102  AC_CHECK_HEADERS(slang.h slang/slang.h,
103   [ac_cv_my_have_slang="yes"
104    AC_DEFINE(USE_SLANG, 1, Define to 1 to activate the slang backend driver)
105    AC_CHECK_LIB(slang, SLsmg_utf8_enable,
106     [AC_DEFINE(HAVE_SLSMG_UTF8_ENABLE, 1, Define to 1 if you have the `SLsmg_utf8_enable' function.)])
107    CPPFLAGS="${CPPFLAGS} -DOPTIMISE_SLANG_PALETTE=1"
108    CACA_LIBS="${CACA_LIBS} -lslang"
109    CACA_DRIVERS="${CACA_DRIVERS} slang"
110    break])
111  if test "${ac_cv_my_have_slang}" = "no" -a "${enable_slang}" = "yes"; then
112    AC_MSG_ERROR([cannot find slang development files])
113  fi
114fi
115
116if test "${enable_x11}" != "no"; then
117  AC_PATH_X
118  AC_CHECK_LIB(X11, XOpenDisplay,
119   [ac_cv_my_have_x11="yes"
120    if test -n "${x_includes}"; then X_CFLAGS="-I${x_includes}"; fi
121    if test -n "${x_libraries}"; then X_LIBS="-lX11 -L${x_libraries}"; fi
122    AC_DEFINE(USE_X11, 1, Define to 1 to activate the X11 backend driver)
123    CPPFLAGS="${CPPFLAGS} ${X_CFLAGS}"
124    CACA_LIBS="${CACA_LIBS} ${X_LIBS}"
125    CACA_DRIVERS="${CACA_DRIVERS} x11"],
126   [ac_cv_my_have_x11="no"],
127   [[-lXt -L${x_libraries}]])
128  AC_CHECK_HEADERS(X11/XKBlib.h)
129  if test "${ac_cv_my_have_x11}" != "yes" -a "${enable_x11}" = "yes"; then
130    AC_MSG_ERROR([cannot find X11 development files])
131  fi
132fi
133
134if test "${enable_gl}" != "no"; then
135  ac_cv_my_have_gl="no"
136  AC_CHECK_HEADERS(GL/gl.h,
137   [AC_CHECK_HEADERS(GL/glut.h,
138     [AC_CHECK_LIB(glut, glutMainLoopEvent,
139       [ac_cv_my_have_gl="yes"
140        AC_DEFINE(USE_GL, 1, Define to 1 to activate the OpenGL backend driver)
141        CACA_LIBS="${CACA_LIBS} -lGL -lglut"
142        CACA_DRIVERS="${CACA_DRIVERS} gl"])])])
143  if test "${ac_cv_my_have_gl}" = "no" -a "${enable_gl}" = "yes"; then
144    AC_MSG_ERROR([cannot find OpenGL+FreeGLUT development files])
145  fi
146fi
147
148if test "${enable_network}" != "no"; then
149  ac_cv_my_have_network="no"
150  AC_CHECK_HEADERS(sys/socket.h,
151     [ac_cv_my_have_network="yes"
152      AC_DEFINE(USE_NETWORK, 1, Define to 1 to activate the network backend driver)
153      CACA_DRIVERS="${CACA_DRIVERS} network"])
154  if test "${ac_cv_my_have_network}" = "no" -a "${enable_network}" = "yes"; then
155    AC_MSG_ERROR([cannot find standard networking socket files])
156  fi
157fi
158
159if test "${enable_ncurses}" != "no"; then
160  ac_cv_my_have_ncurses="no"
161  AC_CHECK_HEADERS(ncursesw/ncurses.h ncurses/ncurses.h ncurses.h curses.h,
162   [ncurses="no"
163    AC_CHECK_LIB(ncursesw, initscr,
164     [ncurses="-lncursesw"],
165     [AC_CHECK_LIB(ncurses, initscr,
166       [ncurses="-lncurses"])])
167    if test "${ncurses}" = "no"; then
168      continue
169    fi
170    ac_cv_my_have_ncurses="yes"
171    AC_DEFINE(USE_NCURSES, 1, Define to 1 to activate the ncurses backend driver)
172    CACA_LIBS="${CACA_LIBS} ${ncurses}"
173    CACA_DRIVERS="${CACA_DRIVERS} ncurses"
174    dnl  Check for resizeterm or resize_term
175    SAVED_LIBS="${LIBS}"
176    LIBS="${LIBS} ${ncurses}"
177    AC_CHECK_FUNCS(resizeterm resize_term)
178    LIBS="${SAVED_LIBS}"
179    break])
180  if test "${ac_cv_my_have_ncurses}" = "no" -a "${enable_ncurses}" = "yes"; then
181    AC_MSG_ERROR([cannot find ncurses development files])
182  fi
183fi
184
185if test "${enable_vga}" = "yes"; then
186  ac_cv_my_have_vga="yes"
187  CPPFLAGS="${CPPFLAGS} -I. -D__KERNEL__ -nostdinc -include kernel/kernel.h"
188  CFLAGS="${CFLAGS} -fno-builtin -O2 -Wall"
189  CCASFLAGS="${CCASFLAGS} -I."
190  LDFLAGS="${LDFLAGS} -nostdlib -Wl,-N -Wl,-Ttext -Wl,100000"
191  AC_DEFINE(USE_VGA, 1, Define to 1 to activate the VGA backend driver)
192  CACA_DRIVERS="${CACA_DRIVERS} vga"
193fi
194AM_CONDITIONAL(USE_KERNEL, test "${ac_cv_my_have_vga}" = "yes")
195
196AC_MSG_CHECKING(valid output drivers)
197if test -z "${CACA_DRIVERS}"; then
198  AC_MSG_RESULT(no)
199  AC_MSG_ERROR([no output drivers were selected!])
200else
201  AC_MSG_RESULT([${CACA_DRIVERS}])
202fi
203
204AC_SUBST(MATH_LIBS)
205AC_SUBST(CACA_LIBS)
206AC_SUBST(CUCUL_LIBS)
207
208# Optimizations
209CFLAGS="${CFLAGS} -g -O2 -fno-strength-reduce -fomit-frame-pointer"
210# Code qui fait des warnings == code de porc == deux baffes dans ta gueule
211# [Jylam] Removed -Wshadow in order to avoid ncurses/gl conflict
212# (Comme quoi on est pas les seuls porcs)
213CFLAGS="${CFLAGS} -Wall -Wpointer-arith -Wcast-align -Wcast-qual -Wstrict-prototypes -Waggregate-return -Wmissing-prototypes -Wnested-externs -Wsign-compare"
214
215# Build the PIC library?
216case "${target_os}" in
217  *mingw32* | *cygwin* | *djgpp*)
218    NEED_PIC=false
219    ;;
220  *)
221    NEED_PIC=:
222    ;;
223esac
224AM_CONDITIONAL(NEED_PIC, ${NEED_PIC})
225
226# Use Imlib2?
227ac_cv_my_have_imlib2="no"
228save_CPPFLAGS="${CPPFLAGS}"
229if test "${enable_imlib2}" != "no"; then
230  AC_PATH_PROG(IMLIB2_CONFIG, imlib2-config, no)
231  if test "${IMLIB2_CONFIG}" != "no"; then
232    CPPFLAGS="${CPPFLAGS} `imlib2-config --cflags` -DX_DISPLAY_MISSING=1"
233  fi
234  AC_CHECK_HEADERS(Imlib2.h,
235    ac_cv_my_have_imlib2="yes",
236   [ac_cv_my_have_imlib2="no"
237    AC_MSG_ERROR([[cannot find Imlib2 development files. Without Imlib2, cacaview will only open BMP files; if this is really what you want, re-run configure with '--disable-imlib2'.]])])
238  CPPFLAGS="${save_CPPFLAGS}"
239fi
240AM_CONDITIONAL(USE_IMLIB2, test "${ac_cv_my_have_imlib2}" = "yes")
241
242# Build documentation?
243DOXYGEN="no"
244LATEX="no"
245if test "${enable_doc}" != "no"; then
246  AC_PATH_PROG(DOXYGEN, doxygen, no)
247  if test "${DOXYGEN}" = "no"; then
248    AC_MSG_ERROR([[cannot find doxygen, which is needed to build the libcaca documentation; if this is really what you want, re-run configure with '--disable-doc'.]])
249  fi
250
251  # Build LaTeX documentation?
252  AC_PATH_PROG(LATEX, latex, no)
253  AC_PATH_PROG(DVIPS, dvips, no)
254  if test "${DVIPS}" = "no"; then
255    LATEX="no"
256  fi
257  AC_MSG_CHECKING(for a4wide.sty)
258  if test -f /usr/share/texmf/tex/latex/misc/a4wide.sty; then
259    AC_MSG_RESULT(yes)
260  elif test -f /usr/share/texmf-tetex/tex/latex/a4wide/a4wide.sty; then
261    AC_MSG_RESULT(yes)
262  else
263    LATEX="no"
264    AC_MSG_RESULT(no)
265  fi
266fi
267AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
268AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")
269
270AC_CONFIG_FILES([
271  Makefile
272  kernel/Makefile
273  cucul/Makefile
274  caca/Makefile
275  src/Makefile
276  test/Makefile
277  doc/Makefile
278  doc/doxygen.cfg
279  autotools/Makefile
280  debian/Makefile
281  msvc/Makefile
282])
283AC_CONFIG_FILES([caca-config], [chmod 0755 caca-config])
284AC_OUTPUT
285
Note: See TracBrowser for help on using the repository browser.