source: libcaca/trunk/configure.ac @ 568

Last change on this file since 568 was 568, checked in by Sam Hocevar, 14 years ago
  • Added glue code to compile libcaca without a libc and build applications as multiboot kernels.
  • Property svn:keywords set to Id
File size: 8.7 KB
Line 
1# $Id: configure.ac 568 2006-03-09 12:47:37Z sam $
2
3AC_INIT(caca/caca.c)
4
5AC_PREREQ(2.50)
6AC_CONFIG_AUX_DIR(autotools)
7AC_CANONICAL_SYSTEM
8
9AM_INIT_AUTOMAKE(libcaca, 0.10)
10AM_CONFIG_HEADER(config.h)
11
12AM_PROG_CC_C_O
13AC_PROG_CPP
14AM_PROG_AS
15
16AC_LIBTOOL_WIN32_DLL
17AM_PROG_LIBTOOL
18
19AC_C_CONST
20AC_C_INLINE
21AC_TYPE_SIGNAL
22
23dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
24dnl now otherwise it might be set in an obscure if statement.
25AC_EGREP_CPP(foo, foo)
26
27dnl output driver features
28AC_ARG_ENABLE(slang,
29  [  --enable-slang          slang graphics support (autodetected)])
30AC_ARG_ENABLE(ncurses,
31  [  --enable-ncurses        ncurses graphics support (autodetected)])
32AC_ARG_ENABLE(win32,
33  [  --enable-win32          Windows console support (autodetected)])
34AC_ARG_ENABLE(conio,
35  [  --enable-conio          DOS conio.h graphics support (autodetected)])
36AC_ARG_ENABLE(x11,
37  [  --enable-x11            X11 support (autodetected)])
38AC_ARG_ENABLE(gl,
39  [  --enable-gl             OpenGL support (autodetected)])
40AC_ARG_ENABLE(network,
41  [  --enable-network        Network support (autodetected)])
42AC_ARG_ENABLE(vga,
43  [  --enable-vga            VGA support (default disabled)])
44
45dnl example programs features
46AC_ARG_ENABLE(imlib2,
47  [  --enable-imlib2         Imlib2 graphics support (default enabled)])
48
49dnl conditional builds
50AC_ARG_ENABLE(doc,
51  [  --enable-doc            build documentation (needs doxygen and LaTeX)])
52
53AC_CHECK_HEADERS(stdio.h stdarg.h signal.h sys/ioctl.h sys/time.h inttypes.h endian.h unistd.h)
54AC_CHECK_FUNCS(signal ioctl vsnprintf getenv putenv strcasecmp)
55AC_CHECK_FUNCS(usleep gettimeofday)
56
57AC_MSG_CHECKING(for Sleep)
58AC_TRY_COMPILE([#include <windows.h>],[Sleep(42);],
59 [AC_MSG_RESULT(yes)
60  AC_DEFINE(HAVE_SLEEP, 1, [Define if you have Windows' Sleep])],
61 [AC_MSG_RESULT(no)])
62AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
63
64CACA_DRIVERS=""
65
66if test "${enable_conio}" != "no"; then
67  ac_cv_my_have_conio="no"
68  AC_CHECK_HEADERS(conio.h,
69   [AC_MSG_CHECKING(for ScreenUpdate in pc.h)
70    AC_EGREP_HEADER(ScreenUpdate, pc.h,
71     [ac_cv_my_have_conio="yes"
72      AC_MSG_RESULT(yes)
73      AC_DEFINE(SCREENUPDATE_IN_PC_H, 1,
74                Define if <pc.h> defines ScreenUpdate.)
75      AC_DEFINE(USE_CONIO, 1, Define to activate the conio.h backend driver)
76      CACA_DRIVERS="${CACA_DRIVERS} conio"],
77     [AC_MSG_RESULT(no)])])
78  if test "${ac_cv_my_have_conio}" = "no" -a "${enable_conio}" = "yes"; then
79    AC_MSG_ERROR([cannot find conio.h])
80  fi
81fi
82
83if test "${enable_win32}" != "no"; then
84  ac_cv_my_have_win32="no"
85  AC_CHECK_HEADERS(windows.h,
86   [AC_MSG_CHECKING(for AllocConsole in windows.h)
87    AC_EGREP_HEADER(AllocConsole, windows.h,
88     [ac_cv_my_have_win32="yes"
89      AC_MSG_RESULT(yes)
90      AC_DEFINE(ALLOCCONSOLE_IN_WINDOWS_H, 1,
91                Define if <windows.h> defines AllocConsole.)
92      AC_DEFINE(USE_WIN32, 1, Define to activate the win32 backend driver)
93      CACA_DRIVERS="${CACA_DRIVERS} win32"],
94     [AC_MSG_RESULT(no)])])
95  if test "${ac_cv_my_have_win32}" = "no" -a "${enable_win32}" = "yes"; then
96    AC_MSG_ERROR([cannot find win32 console development files])
97  fi
98fi
99
100if test "${enable_slang}" != "no"; then
101  ac_cv_my_have_slang="no"
102  AC_CHECK_HEADERS(slang.h slang/slang.h,
103   [AC_CHECK_LIB(slang, SLkp_init,
104     [ac_cv_my_have_slang="yes"
105      AC_DEFINE(USE_SLANG, 1, Define to activate the slang backend driver)
106      CPPFLAGS="${CPPFLAGS} -DOPTIMISE_SLANG_PALETTE=1"
107      CACA_LIBS="${CACA_LIBS} -lslang"
108      CACA_DRIVERS="${CACA_DRIVERS} slang"])])
109  if test "${ac_cv_my_have_slang}" = "no" -a "${enable_slang}" = "yes"; then
110    AC_MSG_ERROR([cannot find slang development files])
111  fi
112fi
113
114if test "${enable_x11}" != "no"; then
115  AC_PATH_X
116  AC_CHECK_LIB(X11, XOpenDisplay,
117   [ac_cv_my_have_x11="yes"
118    if test -n "${x_includes}"; then X_CFLAGS="-I${x_includes}"; fi
119    if test -n "${x_libraries}"; then X_LIBS="-lX11 -L${x_libraries}"; fi
120    AC_DEFINE(USE_X11, 1, Define to activate the X11 backend driver)
121    CPPFLAGS="${CPPFLAGS} ${X_CFLAGS}"
122    CACA_LIBS="${CACA_LIBS} ${X_LIBS}"
123    CACA_DRIVERS="${CACA_DRIVERS} x11"],
124   [ac_cv_my_have_x11="no"],
125   [[-lXt -L${x_libraries}]])
126  AC_CHECK_HEADERS(X11/XKBlib.h)
127  if test "${ac_cv_my_have_x11}" != "yes" -a "${enable_x11}" = "yes"; then
128    AC_MSG_ERROR([cannot find X11 development files])
129  fi
130fi
131
132if test "${enable_gl}" != "no"; then
133  ac_cv_my_have_gl="no"
134  AC_CHECK_HEADERS(GL/gl.h GL/glut.h,
135   [AC_CHECK_LIB(glut, glutMainLoopEvent,
136     [ac_cv_my_have_gl="yes"
137      AC_DEFINE(USE_GL, 1, Define to activate the OpenGL backend driver)
138      CACA_LIBS="${CACA_LIBS} -lGL -lglut"
139      CACA_DRIVERS="${CACA_DRIVERS} gl"])])
140  if test "${ac_cv_my_have_gl}" = "no" -a "${enable_gl}" = "yes"; then
141    AC_MSG_ERROR([cannot find OpenGL+FreeGLUT development files])
142  fi
143fi
144
145if test "${enable_network}" != "no"; then
146  ac_cv_my_have_network="no"
147  AC_CHECK_HEADERS(sys/socket.h,
148     [ac_cv_my_have_network="yes"
149      AC_DEFINE(USE_NETWORK, 1, Define to activate the network backend driver)
150      CACA_DRIVERS="${CACA_DRIVERS} network"])
151  if test "${ac_cv_my_have_network}" = "no" -a "${enable_network}" = "yes"; then
152    AC_MSG_ERROR([cannot find standard networking socket files])
153  fi
154fi
155
156if test "${enable_ncurses}" != "no"; then
157  ac_cv_my_have_ncurses="no"
158  AC_CHECK_HEADERS(curses.h ncurses.h,
159   [AC_CHECK_LIB(ncurses, initscr,
160     [ac_cv_my_have_ncurses="yes"
161      AC_DEFINE(USE_NCURSES, 1, Define to activate the ncurses backend driver)
162      CACA_LIBS="${CACA_LIBS} -lncurses"
163      CACA_DRIVERS="${CACA_DRIVERS} ncurses"
164      dnl  Check for resizeterm or resize_term
165      SAVED_LIBS="${LIBS}"
166      LIBS="${LIBS} -lncurses"
167      AC_CHECK_FUNCS(resizeterm resize_term)
168      LIBS="${SAVED_LIBS}"])])
169  if test "${ac_cv_my_have_ncurses}" = "no" -a "${enable_ncurses}" = "yes"; then
170    AC_MSG_ERROR([cannot find ncurses development files])
171  fi
172fi
173
174if test "${enable_vga}" = "yes"; then
175  ac_cv_my_have_vga="yes"
176  CPPFLAGS="${CPPFLAGS} -I. -D__KERNEL__ -nostdinc -include kernel/kernel.h"
177  CFLAGS="${CFLAGS} -fno-builtin -O2 -Wall"
178  CCASFLAGS="${CCASFLAGS} -I."
179  LDFLAGS="${LDFLAGS} -nostdlib -Wl,-N -Wl,-Ttext -Wl,100000"
180  AC_DEFINE(USE_VGA, 1, Define to activate the VGA backend driver)
181  CACA_DRIVERS="${CACA_DRIVERS} vga"
182fi
183
184AC_MSG_CHECKING(valid output drivers)
185if test -z "${CACA_DRIVERS}"; then
186  AC_MSG_RESULT(no)
187  AC_MSG_ERROR([no output drivers were selected!])
188else
189  AC_MSG_RESULT([${CACA_DRIVERS}])
190fi
191
192AC_SUBST(MATH_LIBS)
193AC_SUBST(CACA_LIBS)
194AC_SUBST(CUCUL_LIBS)
195
196# Optimizations
197CFLAGS="${CFLAGS} -g -O2 -fno-strength-reduce -fomit-frame-pointer"
198# Code qui fait des warnings == code de porc == deux baffes dans ta gueule
199# [Jylam] Removed -Wshadow in order to avoid ncurses/gl conflict
200# (Comme quoi on est pas les seuls porcs)
201CFLAGS="${CFLAGS} -Wall -Wpointer-arith -Wcast-align -Wcast-qual -Wstrict-prototypes -Waggregate-return -Wmissing-prototypes -Wnested-externs -Wsign-compare"
202
203# Build the PIC library?
204case "${target_os}" in
205  *mingw32* | *cygwin* | *djgpp*)
206    NEED_PIC=false
207    ;;
208  *)
209    NEED_PIC=:
210    ;;
211esac
212AM_CONDITIONAL(NEED_PIC, ${NEED_PIC})
213
214# Use Imlib2?
215ac_cv_my_have_imlib2="no"
216save_CPPFLAGS="${CPPFLAGS}"
217if test "${enable_imlib2}" != "no"; then
218  AC_PATH_PROG(IMLIB2_CONFIG, imlib2-config, no)
219  if test "${IMLIB2_CONFIG}" != "no"; then
220    CPPFLAGS="${CPPFLAGS} `imlib2-config --cflags` -DX_DISPLAY_MISSING=1"
221  fi
222  AC_CHECK_HEADERS(Imlib2.h,
223    ac_cv_my_have_imlib2="yes",
224   [ac_cv_my_have_imlib2="no"
225    AC_MSG_ERROR([[cannot find Imlib2 development files. Without Imlib2, cacaview will only open BMP files; if this is really what you want, re-run configure with '--disable-imlib2'.]])])
226  CPPFLAGS="${save_CPPFLAGS}"
227fi
228AM_CONDITIONAL(USE_IMLIB2, test "${ac_cv_my_have_imlib2}" = "yes")
229
230# Build documentation?
231DOXYGEN="no"
232LATEX="no"
233if test "${enable_doc}" != "no"; then
234  AC_PATH_PROG(DOXYGEN, doxygen, no)
235  if test "${DOXYGEN}" = "no"; then
236    AC_MSG_ERROR([[cannot find doxygen, which is needed to build the libcaca documentation; if this is really what you want, re-run configure with '--disable-doc'.]])
237  fi
238
239  # Build LaTeX documentation?
240  AC_PATH_PROG(LATEX, latex, no)
241  AC_PATH_PROG(DVIPS, dvips, no)
242  if test "${DVIPS}" = "no"; then
243    LATEX="no"
244  fi
245  AC_MSG_CHECKING(for a4wide.sty)
246  if test -f /usr/share/texmf/tex/latex/misc/a4wide.sty; then
247    AC_MSG_RESULT(yes)
248  elif test -f /usr/share/texmf-tetex/tex/latex/a4wide/a4wide.sty; then
249    AC_MSG_RESULT(yes)
250  else
251    LATEX="no"
252    AC_MSG_RESULT(no)
253  fi
254fi
255AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
256AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")
257
258AC_CONFIG_FILES([
259  Makefile
260  kernel/Makefile
261  cucul/Makefile
262  caca/Makefile
263  src/Makefile
264  test/Makefile
265  doc/Makefile
266  doc/doxygen.cfg
267  autotools/Makefile
268  debian/Makefile
269  msvc/Makefile
270])
271AC_CONFIG_FILES([caca-config], [chmod 0755 caca-config])
272AC_OUTPUT
273
Note: See TracBrowser for help on using the repository browser.