source: libcaca/trunk/configure.ac @ 2248

Last change on this file since 2248 was 2248, checked in by Sam Hocevar, 12 years ago
  • Don't use mygetopt.c in img2txt if the system has getopt_long.
  • Fix invalid pointer/int cast (Closes #39).
  • Property svn:keywords set to Id
File size: 15.5 KB
Line 
1# $Id: configure.ac 2248 2008-02-29 22:29:08Z sam $
2
3AC_INIT(caca/caca.c)
4
5AC_PREREQ(2.50)
6AC_CONFIG_AUX_DIR(autotools)
7AC_CANONICAL_SYSTEM
8
9AM_INIT_AUTOMAKE(libcaca, 0.99.beta14)
10LT_MAJOR="0"
11LT_MINOR="99"
12LT_MICRO="13"
13AC_SUBST(LT_MAJOR)
14AC_SUBST(LT_MINOR)
15AC_SUBST(LT_MICRO)
16LT_VERSION="$LT_MAJOR:$LT_MINOR:$LT_MICRO"
17AC_SUBST(LT_VERSION)
18AM_CONFIG_HEADER(config.h)
19
20AM_PROG_CC_C_O
21AC_PROG_CPP
22AC_PROG_CXX
23AC_PROG_CXXCPP
24_AM_DEPENDENCIES([OBJC])
25OBJC="${CC}"
26AC_SUBST(OBJC)
27AC_SUBST(OBJCFLAGS)
28AM_PROG_AS
29
30AC_LIBTOOL_WIN32_DLL
31AM_PROG_LIBTOOL
32AC_LIBTOOL_CXX
33
34AC_C_CONST
35AC_C_INLINE
36AC_TYPE_SIGNAL
37
38dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
39dnl now otherwise it might be set in an obscure if statement. Same thing for
40dnl PKG_PROG_PKG_CONFIG which needs to be called first.
41AC_EGREP_CPP(yes, foo)
42PKG_PROG_PKG_CONFIG()
43m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
44if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
45  export PKG_CONFIG_LIBDIR=/dev/null
46fi
47
48dnl output driver features
49AC_ARG_ENABLE(slang,
50  [  --enable-slang          slang graphics support (autodetected)])
51AC_ARG_ENABLE(ncurses,
52  [  --enable-ncurses        ncurses graphics support (autodetected)])
53AC_ARG_ENABLE(win32,
54  [  --enable-win32          Windows console support (autodetected)])
55AC_ARG_ENABLE(conio,
56  [  --enable-conio          DOS conio.h graphics support (autodetected)])
57AC_ARG_ENABLE(x11,
58  [  --enable-x11            X11 support (autodetected)])
59AC_ARG_ENABLE(gl,
60  [  --enable-gl             OpenGL support (autodetected)])
61AC_ARG_ENABLE(cocoa,
62  [  --enable-cocoa          Cocoa support (autodetected)])
63AC_ARG_ENABLE(network,
64  [  --enable-network        Network support (autodetected)])
65AC_ARG_ENABLE(vga,
66  [  --enable-vga            VGA support (default disabled)])
67
68dnl language bindings
69AC_ARG_ENABLE(csharp,
70  [  --enable-csharp         C# bindings (autodetected)])
71AC_ARG_ENABLE(cxx,
72  [  --enable-cxx            C++ bindings (autodetected)])
73AC_ARG_ENABLE(ruby,
74  [  --enable-ruby           Ruby bindings (autodetected)])
75
76dnl example programs features
77AC_ARG_ENABLE(imlib2,
78  [  --enable-imlib2         Imlib2 graphics support (autodetected)])
79
80dnl conditional builds
81AC_ARG_ENABLE(debug,
82  [  --enable-debug          build debug versions of the library (default no)])
83AC_ARG_ENABLE(plugins,
84  [  --enable-plugins        make X11 and GL drivers plugins (default disabled)])
85AC_ARG_ENABLE(doc,
86  [  --enable-doc            build documentation (needs doxygen and LaTeX)])
87AC_ARG_ENABLE(zzuf,
88  [  --enable-zzuf           use zzuf for fuzzing tests (autodetected)])
89
90AC_CHECK_HEADERS(stdio.h stdarg.h signal.h sys/ioctl.h sys/time.h inttypes.h endian.h unistd.h arpa/inet.h netinet/in.h winsock2.h errno.h locale.h getopt.h dlfcn.h termios.h)
91AC_CHECK_FUNCS(signal ioctl snprintf vsnprintf getenv putenv strcasecmp htons)
92AC_CHECK_FUNCS(usleep gettimeofday)
93
94ac_cv_have_getopt_long="no"
95AC_CHECK_FUNCS(getopt_long,
96 [ac_cv_have_getopt_long="yes"],
97 [AC_CHECK_LIB(gnugetopt, getopt_long,
98   [ac_cv_have_getopt_long="yes"
99    GETOPT_LIBS="${GETOPT_LIBS} -lgnugetopt"])])
100if test "$ac_cv_have_getopt_long" != "no"; then
101  AC_DEFINE(HAVE_GETOPT_LONG, 1, Define to 1 if you have the `getopt_long' function.)
102fi
103AM_CONDITIONAL(NEED_GETOPT_LONG, test "$ac_cv_have_getopt_long" = "no")
104AC_SUBST(GETOPT_LIBS)
105
106AC_MSG_CHECKING(for Sleep)
107AC_TRY_COMPILE([#include <windows.h>],[Sleep(42);],
108 [AC_MSG_RESULT(yes)
109  AC_DEFINE(HAVE_SLEEP, 1, [Define to 1 if you have the `Sleep' function.])],
110 [AC_MSG_RESULT(no)])
111
112AC_MSG_CHECKING(for fsin/fcos)
113AC_TRY_COMPILE([],[asm("fsin\n\tfcos");],
114 [AC_MSG_RESULT(yes)
115  AC_DEFINE(HAVE_FSIN_FCOS, 1, [Define to 1 if you have the `fsin' and `fcos' operands.])],
116 [AC_MSG_RESULT(no)])
117
118AC_MSG_CHECKING(for fldln2/fxch/fyl2x)
119AC_TRY_COMPILE([],[asm("fldln2; fldln2; fxch; fyl2x");],
120 [AC_MSG_RESULT(yes)
121  AC_DEFINE(HAVE_FLDLN2, 1, [Define to 1 if you have the `fldln2' and other floating points operands.])],
122 [AC_MSG_RESULT(no)])
123
124AC_CHECK_HEADERS(zlib.h)
125AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="${ZLIB_LIBS} -lz"])
126
127AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
128
129CACA_DRIVERS=""
130
131if test "${enable_conio}" != "no"; then
132  ac_cv_my_have_conio="no"
133  AC_CHECK_HEADERS(conio.h,
134   [AC_MSG_CHECKING(for ScreenUpdate in pc.h)
135    AC_EGREP_HEADER(ScreenUpdate, pc.h,
136     [ac_cv_my_have_conio="yes"
137      AC_MSG_RESULT(yes)
138      AC_DEFINE(SCREENUPDATE_IN_PC_H, 1,
139                Define to 1 if <pc.h> defines ScreenUpdate.)
140      AC_DEFINE(USE_CONIO, 1, Define to 1 to activate the conio.h backend driver)
141      CACA_DRIVERS="${CACA_DRIVERS} conio"],
142     [AC_MSG_RESULT(no)])])
143  if test "${ac_cv_my_have_conio}" = "no" -a "${enable_conio}" = "yes"; then
144    AC_MSG_ERROR([cannot find conio.h])
145  fi
146fi
147
148if test "${enable_win32}" != "no"; then
149  ac_cv_my_have_win32="no"
150  AC_CHECK_HEADERS(windows.h,
151   [AC_MSG_CHECKING(for AllocConsole in windows.h)
152    AC_EGREP_HEADER(AllocConsole, windows.h,
153     [ac_cv_my_have_win32="yes"
154      AC_MSG_RESULT(yes)
155      AC_DEFINE(ALLOCCONSOLE_IN_WINDOWS_H, 1,
156                Define to 1 if <windows.h> defines AllocConsole.)
157      AC_DEFINE(USE_WIN32, 1, Define to 1 to activate the win32 backend driver)
158      CACA_DRIVERS="${CACA_DRIVERS} win32"],
159     [AC_MSG_RESULT(no)])])
160  if test "${ac_cv_my_have_win32}" = "no" -a "${enable_win32}" = "yes"; then
161    AC_MSG_ERROR([cannot find win32 console development files])
162  fi
163fi
164
165if test "${enable_slang}" != "no"; then
166  ac_cv_my_have_slang="no"
167  AC_CHECK_HEADERS(slang.h slang/slang.h,
168   [ac_cv_my_have_slang="yes"
169    AC_DEFINE(USE_SLANG, 1, Define to 1 to activate the slang backend driver)
170    AC_CHECK_LIB(slang, SLsmg_utf8_enable,
171     [AC_DEFINE(HAVE_SLSMG_UTF8_ENABLE, 1, Define to 1 if you have the `SLsmg_utf8_enable' function.)])
172    CPPFLAGS="${CPPFLAGS} -DOPTIMISE_SLANG_PALETTE=1"
173    CACA_LIBS="${CACA_LIBS} -lslang"
174    CACA_DRIVERS="${CACA_DRIVERS} slang"
175    break])
176  if test "${ac_cv_my_have_slang}" = "no" -a "${enable_slang}" = "yes"; then
177    AC_MSG_ERROR([cannot find slang development files])
178  fi
179fi
180
181if test "${enable_x11}" != "no"; then
182  AC_PATH_X
183  AC_CHECK_LIB(X11, XOpenDisplay,
184   [ac_cv_my_have_x11="yes"
185    if test -n "${x_includes}"; then X_CFLAGS="-I${x_includes}"; fi
186    if test -n "${x_libraries}"; then X_LIBS="-L${x_libraries}"; fi
187    AC_DEFINE(USE_X11, 1, Define to 1 to activate the X11 backend driver)
188    CPPFLAGS="${CPPFLAGS} ${X_CFLAGS}"
189    X11_LIBS="${X11_LIBS} -lX11 ${X_LIBS}"
190    CACA_DRIVERS="${CACA_DRIVERS} x11"],
191   [ac_cv_my_have_x11="no"],
192   [[`if test -n "${x_libraries}"; then echo -L${x_libraries}; fi`]])
193  AC_CHECK_HEADERS(X11/XKBlib.h)
194  if test "${ac_cv_my_have_x11}" != "yes" -a "${enable_x11}" = "yes"; then
195    AC_MSG_ERROR([cannot find X11 development files])
196  fi
197fi
198
199if test "${enable_gl}" != "no"; then
200  ac_cv_my_have_gl="no"
201  AC_CHECK_HEADERS(GL/gl.h OpenGL/gl.h,
202   [AC_CHECK_HEADERS(GL/glut.h,
203     [AC_CHECK_LIB(glut, glutCloseFunc,
204       [AC_DEFINE(HAVE_GLUTCLOSEFUNC, 1, Define to 1 if you have the `glutCloseFunc' function.)])
205      AC_CHECK_LIB(glut, glutMainLoopEvent,
206       [ac_cv_my_have_gl="yes"])
207      AC_CHECK_LIB(glut, glutCheckLoop,
208       [ac_cv_my_have_gl="yes"
209        AC_DEFINE(HAVE_GLUTCHECKLOOP, 1, Define to 1 if you have the `glutCheckLoop' function.)])])
210      break])
211  if test "${ac_cv_my_have_gl}" = "yes"; then
212    AC_DEFINE(USE_GL, 1, Define to 1 to activate the OpenGL backend driver)
213    GL_LIBS="${GL_LIBS} -lGL -lglut"
214    CACA_DRIVERS="${CACA_DRIVERS} gl"
215  elif test "${enable_gl}" = "yes"; then
216    AC_MSG_ERROR([cannot find OpenGL+FreeGLUT development files])
217  fi
218fi
219
220if test "${enable_cocoa}" != "no"; then
221  ac_cv_my_have_cocoa="no"
222  AC_CHECK_HEADERS(Cocoa/Cocoa.h,
223   [ac_cv_my_have_cocoa="yes"])
224  if test "${ac_cv_my_have_cocoa}" = "yes"; then
225    case x${target} in
226    xpowerpc*darwin*)
227      # 10.3 needed to link with X11
228      MACOSX_SDK=/Developer/SDKs/MacOSX10.3.9.sdk
229      GCC_VERSION=3.3
230      ARCH="-arch ppc"
231      MACOSX_SDK_CFLAGS="-nostdinc -isystem ${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION} -isystem ${MACOSX_SDK}/usr/include"
232      MACOSX_SDK_CXXFLAGS="-nostdinc++ -I${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION}/c++ -I${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION}/c++/ppc-darwin -I${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION}/c++/backward"
233      MACOSX_SDK_LDFLAGS="-L${MACOSX_SDK}/usr/lib/gcc/darwin -L${MACOSX_SDK}/usr/lib/gcc/darwin/${GCC_VERSION} -L${MACOSX_SDK}/usr/lib"
234      ;;
235    x*86*darwin*)
236      MACOSX_SDK=/Developer/SDKs/MacOSX10.4u.sdk
237      GCC_VERSION=4.0
238      ARCH="-arch i386"
239      MACOSX_SDK_CFLAGS="-isysroot ${MACOSX_SDK}"
240      MACOSX_SDK_CXXFLAGS="${MACOSX_SDK_CFLAGS}"
241      ;;
242    esac
243    CC=gcc-${GCC_VERSION}
244    CXX=g++-${GCC_VERSION}
245    MACOSX_SDK_FRAMEWORKS="-F${MACOSX_SDK}/System/Library/Frameworks"
246    CPPFLAGS="${CPPFLAGS} ${ARCH} ${MACOSX_SDK_FRAMEWORKS}"
247    CFLAGS="${CFLAGS} ${MACOSX_SDK_CFLAGS}"
248    CXXFLAGS="${CXXFLAGS} ${MACOSX_SDK_CXXFLAGS}"
249    OBJCFLAGS="${OBJCFLAGS} ${MACOSX_SDK_CFLAGS}"
250    LDFLAGS="${ARCH} ${MACOSX_SDK_LDFLAGS} ${LDFLAGS}"
251    AC_DEFINE(USE_COCOA, 1, Define to 1 to activate the Cocoa backend driver)
252    CACA_LIBS="${CACA_LIBS} -Wl,-syslibroot,${MACOSX_SDK},-framework,Cocoa"
253    CACA_DRIVERS="${CACA_DRIVERS} cocoa"
254  elif test "${enable_cocoa}" = "yes"; then
255    AC_MSG_ERROR([cannot find Cocoa development files])
256  fi
257fi
258AM_CONDITIONAL(USE_COCOA, test "${ac_cv_my_have_cocoa}" = "yes")
259
260if test "${enable_ncurses}" != "no"; then
261  ac_cv_my_have_ncurses="no"
262  AC_CHECK_HEADERS(ncursesw/ncurses.h ncurses/ncurses.h ncurses.h curses.h,
263   [ncurses="no"
264    AC_CHECK_LIB(ncursesw, initscr,
265     [ncurses="-lncursesw"],
266     [AC_CHECK_LIB(ncurses, initscr,
267       [ncurses="-lncurses"])])
268    if test "${ncurses}" = "no"; then
269      continue
270    fi
271    ac_cv_my_have_ncurses="yes"
272    AC_DEFINE(USE_NCURSES, 1, Define to 1 to activate the ncurses backend driver)
273    CACA_LIBS="${CACA_LIBS} ${ncurses}"
274    CACA_DRIVERS="${CACA_DRIVERS} ncurses"
275    dnl  Check for resizeterm or resize_term
276    SAVED_LIBS="${LIBS}"
277    LIBS="${LIBS} ${ncurses}"
278    AC_CHECK_FUNCS(resizeterm resize_term)
279    LIBS="${SAVED_LIBS}"
280    break])
281  if test "${ac_cv_my_have_ncurses}" = "no" -a "${enable_ncurses}" = "yes"; then
282    AC_MSG_ERROR([cannot find ncurses development files])
283  fi
284fi
285
286if test "${enable_vga}" = "yes"; then
287  ac_cv_my_have_vga="yes"
288  CPPFLAGS="${CPPFLAGS} -I. -D__KERNEL__ -nostdinc -include kernel/kernel.h"
289  CFLAGS="${CFLAGS} -fno-builtin -O2 -Wall"
290  CCASFLAGS="${CCASFLAGS} -I."
291  LDFLAGS="${LDFLAGS} -nostdlib -Wl,-N -Wl,-Ttext -Wl,100000"
292  AC_DEFINE(USE_VGA, 1, Define to 1 to activate the VGA backend driver)
293  CACA_DRIVERS="${CACA_DRIVERS} vga"
294fi
295AM_CONDITIONAL(USE_KERNEL, test "${ac_cv_my_have_vga}" = "yes")
296
297if test "${enable_debug}" = "yes"; then
298  AC_DEFINE(DEBUG, 1, Define to 1 to activate debug)
299fi
300
301if test "${enable_plugins}" = "yes"; then
302  ac_cv_my_have_plugins="yes"
303  AC_DEFINE(USE_PLUGINS, 1, Define to 1 to activate plugins)
304  CACA_LIBS="${CACA_LIBS} -ldl"
305else
306  CACA_LIBS="${CACA_LIBS} ${X11_LIBS} ${GL_LIBS}"
307fi
308AM_CONDITIONAL(USE_PLUGINS, test "${ac_cv_my_have_plugins}" = "yes")
309
310AC_MSG_CHECKING(valid output drivers)
311if test -z "${CACA_DRIVERS}"; then
312  AC_MSG_RESULT(no)
313  AC_MSG_ERROR([no output drivers were selected!])
314else
315  CACA_DRIVERS="${CACA_DRIVERS# *}"
316  AC_MSG_RESULT([${CACA_DRIVERS}])
317fi
318
319AC_SUBST(MATH_LIBS)
320AC_SUBST(ZLIB_LIBS)
321AC_SUBST(GETOPT_LIBS)
322AC_SUBST(CACA_LIBS)
323AC_SUBST(X11_LIBS)
324AC_SUBST(GL_LIBS)
325
326# Optimizations
327CFLAGS="${CFLAGS} -g -O2 -fno-strength-reduce -fomit-frame-pointer"
328# Code qui fait des warnings == code de porc == deux baffes dans ta gueule
329# [Jylam] Removed -Wshadow in order to avoid ncurses/gl conflict
330# (Comme quoi on n'est pas les seuls porcs)
331CFLAGS="${CFLAGS} -Wall -Wpointer-arith -Wcast-align -Wcast-qual -Wstrict-prototypes -Wshadow -Waggregate-return -Wmissing-prototypes -Wnested-externs -Wsign-compare"
332
333CACA_BINDINGS=""
334
335# Build the C++ bindings?
336ac_cv_my_have_cxx="no"
337if test "${enable_cxx}" != "no"; then
338  AC_MSG_CHECKING([working <iostream>])
339  AC_LANG_PUSH(C++)
340  AC_TRY_COMPILE(
341   [#include <iostream>],
342   [],
343   [ac_cv_my_have_cxx="yes"
344    CACA_BINDINGS="${CACA_BINDINGS} C++"])
345  AC_LANG_POP(C++)
346  AC_MSG_RESULT([$ac_cv_my_have_cxx])
347fi
348AM_CONDITIONAL(USE_CXX, test "${ac_cv_my_have_cxx}" = "yes")
349
350# Build the .NET bindings?
351ac_cv_my_have_csharp="no"
352if test "${enable_csharp}" != "no"; then
353  AC_PATH_PROG(GMCS, gmcs, no)
354  AC_PATH_PROG(GACUTIL, gacutil, no)
355  if test "${GMCS}" != "no" -a "${GACUTIL}" != "no"; then
356    ac_cv_my_have_csharp="yes"
357    CACA_BINDINGS="${CACA_BINDINGS} C#"
358  fi
359fi
360AM_CONDITIONAL(USE_CSHARP, test "${ac_cv_my_have_csharp}" = "yes")
361
362# Build the Ruby bindings?
363ac_cv_my_have_ruby="no"
364if test "${enable_ruby}" != "no"; then
365  AC_PATH_PROG(RUBY, ruby, no)
366  if test "${RUBY}" != "no"; then
367    RUBY_CFLAGS="-I$(ruby -r rbconfig -e 'print Config::CONFIG@<:@"archdir"@:>@')"
368    RUBY_LIBS="-L$(ruby -r rbconfig -e 'print Config::CONFIG@<:@"libdir"@:>@') -l$(ruby -r rbconfig -e 'print Config::CONFIG@<:@"RUBY_SO_NAME"@:>@')"
369    RUBY_SITEARCHDIR=`ruby -r rbconfig -e 'print Config::CONFIG@<:@"sitearchdir"@:>@'`
370    RUBY_SITELIBDIR=`ruby -r rbconfig -e 'print Config::CONFIG@<:@"sitelibdir"@:>@'`
371    AC_SUBST(RUBY_CFLAGS)
372    AC_SUBST(RUBY_LIBS)
373    AC_SUBST(RUBY_SITEARCHDIR)
374    AC_SUBST(RUBY_SITELIBDIR)
375    CPPFLAGS="${CPPFLAGS} ${RUBY_CFLAGS}"
376    AC_CHECK_HEADERS([ruby.h],
377     [ac_cv_my_have_ruby="yes"
378      CACA_BINDINGS="${CACA_BINDINGS} Ruby"])
379  fi
380fi
381AM_CONDITIONAL(USE_RUBY, test "${ac_cv_my_have_ruby}" = "yes")
382
383AC_MSG_CHECKING(available language bindings)
384if test -z "${CACA_BINDINGS}"; then
385  AC_MSG_RESULT(no)
386else
387  CACA_BINDINGS="${CACA_BINDINGS# *}"
388  AC_MSG_RESULT([${CACA_BINDINGS}])
389fi
390
391# Build cacaserver?
392ac_cv_my_have_network="no"
393AC_CHECK_HEADERS(sys/socket.h,
394 [ac_cv_my_have_network="yes"])
395AM_CONDITIONAL(USE_NETWORK, test "${ac_cv_my_have_network}" = "yes")
396
397# Use Imlib2?
398if test "${enable_imlib2}" != "no"; then
399  IMLIB2="no"
400  PKG_CHECK_MODULES(IMLIB2, imlib2, [IMLIB2="yes"], [AC_MSG_RESULT(no)])
401  if test "${IMLIB2}" != "no"; then
402    AC_DEFINE(USE_IMLIB2, 1, Define to 1 to use Imlib2)
403  fi
404fi
405
406# Build development tools?
407PANGOFT2="no"
408PKG_CHECK_MODULES(PANGOFT2, pangoft2, [PANGOFT2="yes"], [AC_MSG_RESULT(no)])
409AM_CONDITIONAL(USE_PANGO, test "${PANGOFT2}" != "no")
410
411# Build documentation?
412DOXYGEN="no"
413LATEX="no"
414if test "${enable_doc}" != "no"; then
415  AC_PATH_PROG(DOXYGEN, doxygen, no)
416  if test "${DOXYGEN}" != "no"; then
417    # Build LaTeX documentation?
418    AC_PATH_PROG(LATEX, pdflatex, no)
419    AC_PATH_PROG(KPSEWHICH, kpsewhich, no)
420    AC_PATH_PROG(DVIPS, dvips, no)
421    if test "${DVIPS}" = "no" -o "${KPSEWHICH}" = "no"; then
422      LATEX="no"
423    fi
424    if test "${LATEX}" != "no"; then
425      AC_MSG_CHECKING(for a4.sty and a4wide.sty)
426      if "${KPSEWHICH}" a4.sty >/dev/null 2>&1; then
427        if "${KPSEWHICH}" a4wide.sty >/dev/null 2>&1; then
428          AC_MSG_RESULT(yes)
429        else
430          LATEX="no"
431          AC_MSG_RESULT(no)
432        fi
433      else
434        LATEX="no"
435        AC_MSG_RESULT(no)
436      fi
437    fi
438  fi
439fi
440AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
441AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")
442
443# Use zzuf for fuzzing tests?
444ZZUF="no"
445if test "${enable_zzuf}" != "no"; then
446  AC_PATH_PROG(ZZUF, zzuf, no)
447fi
448AM_CONDITIONAL(USE_ZZUF, test "${ZZUF}" != "no")
449
450AC_CONFIG_FILES([
451  Makefile
452  kernel/Makefile
453  cucul/Makefile
454  caca/Makefile
455  src/Makefile
456  examples/Makefile
457  tests/Makefile
458  tools/Makefile
459  csharp/Makefile
460  cxx/Makefile
461  python/Makefile
462  ruby/Makefile
463  doc/Makefile
464  msvc/Makefile
465])
466AC_CONFIG_FILES([
467  cucul/cucul.pc
468  caca/caca.pc
469  csharp/cucul-sharp.dll.config
470  csharp/caca-sharp.dll.config
471  doc/doxygen.cfg
472])
473AC_CONFIG_FILES([caca-config], [chmod 0755 caca-config])
474AC_OUTPUT
475
Note: See TracBrowser for help on using the repository browser.