source: libcaca/trunk/configure.ac @ 2137

Last change on this file since 2137 was 2109, checked in by Sam Hocevar, 12 years ago
  • Import io.c from TOIlet directly into libcucul. Can you see where this is going?
  • Property svn:keywords set to Id
File size: 15.4 KB
Line 
1# $Id: configure.ac 2109 2007-12-01 17:57:50Z sam $
2
3AC_INIT(caca/caca.c)
4
5AC_PREREQ(2.50)
6AC_CONFIG_AUX_DIR(autotools)
7AC_CANONICAL_SYSTEM
8
9AM_INIT_AUTOMAKE(libcaca, 0.99.beta14)
10LT_MAJOR="0"
11LT_MINOR="99"
12LT_MICRO="13"
13AC_SUBST(LT_MAJOR)
14AC_SUBST(LT_MINOR)
15AC_SUBST(LT_MICRO)
16LT_VERSION="$LT_MAJOR:$LT_MINOR:$LT_MICRO"
17AC_SUBST(LT_VERSION)
18AM_CONFIG_HEADER(config.h)
19
20AM_PROG_CC_C_O
21AC_PROG_CPP
22AC_PROG_CXX
23AC_PROG_CXXCPP
24_AM_DEPENDENCIES([OBJC])
25OBJC="${CC}"
26AC_SUBST(OBJC)
27AC_SUBST(OBJCFLAGS)
28AM_PROG_AS
29
30AC_LIBTOOL_WIN32_DLL
31AM_PROG_LIBTOOL
32AC_LIBTOOL_CXX
33
34AC_C_CONST
35AC_C_INLINE
36AC_TYPE_SIGNAL
37
38dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
39dnl now otherwise it might be set in an obscure if statement. Same thing for
40dnl PKG_PROG_PKG_CONFIG which needs to be called first.
41AC_EGREP_CPP(yes, foo)
42PKG_PROG_PKG_CONFIG()
43m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
44if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
45  export PKG_CONFIG_LIBDIR=/dev/null
46fi
47
48dnl output driver features
49AC_ARG_ENABLE(slang,
50  [  --enable-slang          slang graphics support (autodetected)])
51AC_ARG_ENABLE(ncurses,
52  [  --enable-ncurses        ncurses graphics support (autodetected)])
53AC_ARG_ENABLE(win32,
54  [  --enable-win32          Windows console support (autodetected)])
55AC_ARG_ENABLE(conio,
56  [  --enable-conio          DOS conio.h graphics support (autodetected)])
57AC_ARG_ENABLE(x11,
58  [  --enable-x11            X11 support (autodetected)])
59AC_ARG_ENABLE(gl,
60  [  --enable-gl             OpenGL support (autodetected)])
61AC_ARG_ENABLE(cocoa,
62  [  --enable-cocoa          Cocoa support (autodetected)])
63AC_ARG_ENABLE(network,
64  [  --enable-network        Network support (autodetected)])
65AC_ARG_ENABLE(vga,
66  [  --enable-vga            VGA support (default disabled)])
67
68dnl language bindings
69AC_ARG_ENABLE(csharp,
70  [  --enable-csharp         C# bindings (autodetected)])
71AC_ARG_ENABLE(cxx,
72  [  --enable-cxx            C++ bindings (autodetected)])
73AC_ARG_ENABLE(ruby,
74  [  --enable-ruby           Ruby bindings (autodetected)])
75
76dnl example programs features
77AC_ARG_ENABLE(imlib2,
78  [  --enable-imlib2         Imlib2 graphics support (autodetected)])
79
80dnl conditional builds
81AC_ARG_ENABLE(debug,
82  [  --enable-debug          build debug versions of the library (default no)])
83AC_ARG_ENABLE(plugins,
84  [  --enable-plugins        make X11 and GL drivers plugins (default disabled)])
85AC_ARG_ENABLE(doc,
86  [  --enable-doc            build documentation (needs doxygen and LaTeX)])
87AC_ARG_ENABLE(zzuf,
88  [  --enable-zzuf           use zzuf for fuzzing tests (autodetected)])
89
90AC_CHECK_HEADERS(stdio.h stdarg.h signal.h sys/ioctl.h sys/time.h inttypes.h endian.h unistd.h arpa/inet.h netinet/in.h winsock2.h errno.h locale.h getopt.h dlfcn.h termios.h)
91AC_CHECK_FUNCS(signal ioctl vsnprintf getenv putenv strcasecmp htons)
92AC_CHECK_FUNCS(usleep gettimeofday)
93
94AC_CHECK_FUNCS(getopt_long,
95 [AC_DEFINE(HAVE_GETOPT_LONG, 1, Define to 1 if you have the `getopt_long' function.)],
96 [AC_CHECK_LIB(gnugetopt, getopt_long,
97   [AC_DEFINE(HAVE_GETOPT_LONG, 1, Define to 1 if you have the `getopt_long' function.)
98    GETOPT_LIBS="${GETOPT_LIBS} -lgnugetopt"])])
99AC_SUBST(GETOPT_LIBS)
100
101AC_MSG_CHECKING(for Sleep)
102AC_TRY_COMPILE([#include <windows.h>],[Sleep(42);],
103 [AC_MSG_RESULT(yes)
104  AC_DEFINE(HAVE_SLEEP, 1, [Define to 1 if you have the `Sleep' function.])],
105 [AC_MSG_RESULT(no)])
106
107AC_MSG_CHECKING(for fsin/fcos)
108AC_TRY_COMPILE([],[asm("fsin\n\tfcos");],
109 [AC_MSG_RESULT(yes)
110  AC_DEFINE(HAVE_FSIN_FCOS, 1, [Define to 1 if you have the `fsin' and `fcos' operands.])],
111 [AC_MSG_RESULT(no)])
112
113AC_MSG_CHECKING(for fldln2/fxch/fyl2x)
114AC_TRY_COMPILE([],[asm("fldln2; fldln2; fxch; fyl2x");],
115 [AC_MSG_RESULT(yes)
116  AC_DEFINE(HAVE_FLDLN2, 1, [Define to 1 if you have the `fldln2' and other floating points operands.])],
117 [AC_MSG_RESULT(no)])
118
119AC_CHECK_HEADERS(zlib.h)
120AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="${ZLIB_LIBS} -lz"])
121
122AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
123
124CACA_DRIVERS=""
125
126if test "${enable_conio}" != "no"; then
127  ac_cv_my_have_conio="no"
128  AC_CHECK_HEADERS(conio.h,
129   [AC_MSG_CHECKING(for ScreenUpdate in pc.h)
130    AC_EGREP_HEADER(ScreenUpdate, pc.h,
131     [ac_cv_my_have_conio="yes"
132      AC_MSG_RESULT(yes)
133      AC_DEFINE(SCREENUPDATE_IN_PC_H, 1,
134                Define to 1 if <pc.h> defines ScreenUpdate.)
135      AC_DEFINE(USE_CONIO, 1, Define to 1 to activate the conio.h backend driver)
136      CACA_DRIVERS="${CACA_DRIVERS} conio"],
137     [AC_MSG_RESULT(no)])])
138  if test "${ac_cv_my_have_conio}" = "no" -a "${enable_conio}" = "yes"; then
139    AC_MSG_ERROR([cannot find conio.h])
140  fi
141fi
142
143if test "${enable_win32}" != "no"; then
144  ac_cv_my_have_win32="no"
145  AC_CHECK_HEADERS(windows.h,
146   [AC_MSG_CHECKING(for AllocConsole in windows.h)
147    AC_EGREP_HEADER(AllocConsole, windows.h,
148     [ac_cv_my_have_win32="yes"
149      AC_MSG_RESULT(yes)
150      AC_DEFINE(ALLOCCONSOLE_IN_WINDOWS_H, 1,
151                Define to 1 if <windows.h> defines AllocConsole.)
152      AC_DEFINE(USE_WIN32, 1, Define to 1 to activate the win32 backend driver)
153      CACA_DRIVERS="${CACA_DRIVERS} win32"],
154     [AC_MSG_RESULT(no)])])
155  if test "${ac_cv_my_have_win32}" = "no" -a "${enable_win32}" = "yes"; then
156    AC_MSG_ERROR([cannot find win32 console development files])
157  fi
158fi
159
160if test "${enable_slang}" != "no"; then
161  ac_cv_my_have_slang="no"
162  AC_CHECK_HEADERS(slang.h slang/slang.h,
163   [ac_cv_my_have_slang="yes"
164    AC_DEFINE(USE_SLANG, 1, Define to 1 to activate the slang backend driver)
165    AC_CHECK_LIB(slang, SLsmg_utf8_enable,
166     [AC_DEFINE(HAVE_SLSMG_UTF8_ENABLE, 1, Define to 1 if you have the `SLsmg_utf8_enable' function.)])
167    CPPFLAGS="${CPPFLAGS} -DOPTIMISE_SLANG_PALETTE=1"
168    CACA_LIBS="${CACA_LIBS} -lslang"
169    CACA_DRIVERS="${CACA_DRIVERS} slang"
170    break])
171  if test "${ac_cv_my_have_slang}" = "no" -a "${enable_slang}" = "yes"; then
172    AC_MSG_ERROR([cannot find slang development files])
173  fi
174fi
175
176if test "${enable_x11}" != "no"; then
177  AC_PATH_X
178  AC_CHECK_LIB(X11, XOpenDisplay,
179   [ac_cv_my_have_x11="yes"
180    if test -n "${x_includes}"; then X_CFLAGS="-I${x_includes}"; fi
181    if test -n "${x_libraries}"; then X_LIBS="-L${x_libraries}"; fi
182    AC_DEFINE(USE_X11, 1, Define to 1 to activate the X11 backend driver)
183    CPPFLAGS="${CPPFLAGS} ${X_CFLAGS}"
184    X11_LIBS="${X11_LIBS} -lX11 ${X_LIBS}"
185    CACA_DRIVERS="${CACA_DRIVERS} x11"],
186   [ac_cv_my_have_x11="no"],
187   [[`if test -n "${x_libraries}"; then echo -L${x_libraries}; fi`]])
188  AC_CHECK_HEADERS(X11/XKBlib.h)
189  if test "${ac_cv_my_have_x11}" != "yes" -a "${enable_x11}" = "yes"; then
190    AC_MSG_ERROR([cannot find X11 development files])
191  fi
192fi
193
194if test "${enable_gl}" != "no"; then
195  ac_cv_my_have_gl="no"
196  AC_CHECK_HEADERS(GL/gl.h OpenGL/gl.h,
197   [AC_CHECK_HEADERS(GL/glut.h,
198     [AC_CHECK_LIB(glut, glutCloseFunc,
199       [AC_DEFINE(HAVE_GLUTCLOSEFUNC, 1, Define to 1 if you have the `glutCloseFunc' function.)])
200      AC_CHECK_LIB(glut, glutMainLoopEvent,
201       [ac_cv_my_have_gl="yes"])
202      AC_CHECK_LIB(glut, glutCheckLoop,
203       [ac_cv_my_have_gl="yes"
204        AC_DEFINE(HAVE_GLUTCHECKLOOP, 1, Define to 1 if you have the `glutCheckLoop' function.)])])
205      break])
206  if test "${ac_cv_my_have_gl}" = "yes"; then
207    AC_DEFINE(USE_GL, 1, Define to 1 to activate the OpenGL backend driver)
208    GL_LIBS="${GL_LIBS} -lGL -lglut"
209    CACA_DRIVERS="${CACA_DRIVERS} gl"
210  elif test "${enable_gl}" = "yes"; then
211    AC_MSG_ERROR([cannot find OpenGL+FreeGLUT development files])
212  fi
213fi
214
215if test "${enable_cocoa}" != "no"; then
216  ac_cv_my_have_cocoa="no"
217  AC_CHECK_HEADERS(Cocoa/Cocoa.h,
218   [ac_cv_my_have_cocoa="yes"])
219  if test "${ac_cv_my_have_cocoa}" = "yes"; then
220    case x${target} in
221    xpowerpc*darwin*)
222      # 10.3 needed to link with X11
223      MACOSX_SDK=/Developer/SDKs/MacOSX10.3.9.sdk
224      GCC_VERSION=3.3
225      ARCH="-arch ppc"
226      MACOSX_SDK_CFLAGS="-nostdinc -isystem ${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION} -isystem ${MACOSX_SDK}/usr/include"
227      MACOSX_SDK_CXXFLAGS="-nostdinc++ -I${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION}/c++ -I${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION}/c++/ppc-darwin -I${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION}/c++/backward"
228      MACOSX_SDK_LDFLAGS="-L${MACOSX_SDK}/usr/lib/gcc/darwin -L${MACOSX_SDK}/usr/lib/gcc/darwin/${GCC_VERSION} -L${MACOSX_SDK}/usr/lib"
229      ;;
230    x*86*darwin*)
231      MACOSX_SDK=/Developer/SDKs/MacOSX10.4u.sdk
232      GCC_VERSION=4.0
233      ARCH="-arch i386"
234      MACOSX_SDK_CFLAGS="-isysroot ${MACOSX_SDK}"
235      MACOSX_SDK_CXXFLAGS="${MACOSX_SDK_CFLAGS}"
236      ;;
237    esac
238    CC=gcc-${GCC_VERSION}
239    CXX=g++-${GCC_VERSION}
240    MACOSX_SDK_FRAMEWORKS="-F${MACOSX_SDK}/System/Library/Frameworks"
241    CPPFLAGS="${CPPFLAGS} ${ARCH} ${MACOSX_SDK_FRAMEWORKS}"
242    CFLAGS="${CFLAGS} ${MACOSX_SDK_CFLAGS}"
243    CXXFLAGS="${CXXFLAGS} ${MACOSX_SDK_CXXFLAGS}"
244    OBJCFLAGS="${OBJCFLAGS} ${MACOSX_SDK_CFLAGS}"
245    LDFLAGS="${ARCH} ${MACOSX_SDK_LDFLAGS} ${LDFLAGS}"
246    AC_DEFINE(USE_COCOA, 1, Define to 1 to activate the Cocoa backend driver)
247    CACA_LIBS="${CACA_LIBS} -Wl,-syslibroot,${MACOSX_SDK},-framework,Cocoa"
248    CACA_DRIVERS="${CACA_DRIVERS} cocoa"
249  elif test "${enable_cocoa}" = "yes"; then
250    AC_MSG_ERROR([cannot find Cocoa development files])
251  fi
252fi
253AM_CONDITIONAL(USE_COCOA, test "${ac_cv_my_have_cocoa}" = "yes")
254
255if test "${enable_ncurses}" != "no"; then
256  ac_cv_my_have_ncurses="no"
257  AC_CHECK_HEADERS(ncursesw/ncurses.h ncurses/ncurses.h ncurses.h curses.h,
258   [ncurses="no"
259    AC_CHECK_LIB(ncursesw, initscr,
260     [ncurses="-lncursesw"],
261     [AC_CHECK_LIB(ncurses, initscr,
262       [ncurses="-lncurses"])])
263    if test "${ncurses}" = "no"; then
264      continue
265    fi
266    ac_cv_my_have_ncurses="yes"
267    AC_DEFINE(USE_NCURSES, 1, Define to 1 to activate the ncurses backend driver)
268    CACA_LIBS="${CACA_LIBS} ${ncurses}"
269    CACA_DRIVERS="${CACA_DRIVERS} ncurses"
270    dnl  Check for resizeterm or resize_term
271    SAVED_LIBS="${LIBS}"
272    LIBS="${LIBS} ${ncurses}"
273    AC_CHECK_FUNCS(resizeterm resize_term)
274    LIBS="${SAVED_LIBS}"
275    break])
276  if test "${ac_cv_my_have_ncurses}" = "no" -a "${enable_ncurses}" = "yes"; then
277    AC_MSG_ERROR([cannot find ncurses development files])
278  fi
279fi
280
281if test "${enable_vga}" = "yes"; then
282  ac_cv_my_have_vga="yes"
283  CPPFLAGS="${CPPFLAGS} -I. -D__KERNEL__ -nostdinc -include kernel/kernel.h"
284  CFLAGS="${CFLAGS} -fno-builtin -O2 -Wall"
285  CCASFLAGS="${CCASFLAGS} -I."
286  LDFLAGS="${LDFLAGS} -nostdlib -Wl,-N -Wl,-Ttext -Wl,100000"
287  AC_DEFINE(USE_VGA, 1, Define to 1 to activate the VGA backend driver)
288  CACA_DRIVERS="${CACA_DRIVERS} vga"
289fi
290AM_CONDITIONAL(USE_KERNEL, test "${ac_cv_my_have_vga}" = "yes")
291
292if test "${enable_debug}" = "yes"; then
293  AC_DEFINE(DEBUG, 1, Define to 1 to activate debug)
294fi
295
296if test "${enable_plugins}" = "yes"; then
297  ac_cv_my_have_plugins="yes"
298  AC_DEFINE(USE_PLUGINS, 1, Define to 1 to activate plugins)
299  CACA_LIBS="${CACA_LIBS} -ldl"
300else
301  CACA_LIBS="${CACA_LIBS} ${X11_LIBS} ${GL_LIBS}"
302fi
303AM_CONDITIONAL(USE_PLUGINS, test "${ac_cv_my_have_plugins}" = "yes")
304
305AC_MSG_CHECKING(valid output drivers)
306if test -z "${CACA_DRIVERS}"; then
307  AC_MSG_RESULT(no)
308  AC_MSG_ERROR([no output drivers were selected!])
309else
310  CACA_DRIVERS="${CACA_DRIVERS# *}"
311  AC_MSG_RESULT([${CACA_DRIVERS}])
312fi
313
314AC_SUBST(MATH_LIBS)
315AC_SUBST(ZLIB_LIBS)
316AC_SUBST(GETOPT_LIBS)
317AC_SUBST(CACA_LIBS)
318AC_SUBST(X11_LIBS)
319AC_SUBST(GL_LIBS)
320
321# Optimizations
322CFLAGS="${CFLAGS} -g -O2 -fno-strength-reduce -fomit-frame-pointer"
323# Code qui fait des warnings == code de porc == deux baffes dans ta gueule
324# [Jylam] Removed -Wshadow in order to avoid ncurses/gl conflict
325# (Comme quoi on n'est pas les seuls porcs)
326CFLAGS="${CFLAGS} -Wall -Wpointer-arith -Wcast-align -Wcast-qual -Wstrict-prototypes -Wshadow -Waggregate-return -Wmissing-prototypes -Wnested-externs -Wsign-compare"
327
328CACA_BINDINGS=""
329
330# Build the C++ bindings?
331ac_cv_my_have_cxx="no"
332if test "${enable_cxx}" != "no"; then
333  AC_MSG_CHECKING([working <iostream>])
334  AC_LANG_PUSH(C++)
335  AC_TRY_COMPILE(
336   [#include <iostream>],
337   [],
338   [ac_cv_my_have_cxx="yes"
339    CACA_BINDINGS="${CACA_BINDINGS} C++"])
340  AC_LANG_POP(C++)
341  AC_MSG_RESULT([$ac_cv_my_have_cxx])
342fi
343AM_CONDITIONAL(USE_CXX, test "${ac_cv_my_have_cxx}" = "yes")
344
345# Build the .NET bindings?
346ac_cv_my_have_csharp="no"
347if test "${enable_csharp}" != "no"; then
348  AC_PATH_PROG(GMCS, gmcs, no)
349  AC_PATH_PROG(GACUTIL, gacutil, no)
350  if test "${GMCS}" != "no" -a "${GACUTIL}" != "no"; then
351    ac_cv_my_have_csharp="yes"
352    CACA_BINDINGS="${CACA_BINDINGS} C#"
353  fi
354fi
355AM_CONDITIONAL(USE_CSHARP, test "${ac_cv_my_have_csharp}" = "yes")
356
357# Build the Ruby bindings?
358ac_cv_my_have_ruby="no"
359if test "${enable_ruby}" != "no"; then
360  AC_PATH_PROG(RUBY, ruby, no)
361  if test "${RUBY}" != "no"; then
362    RUBY_CFLAGS="-I$(ruby -r rbconfig -e 'print Config::CONFIG@<:@"archdir"@:>@')"
363    RUBY_LIBS="-L$(ruby -r rbconfig -e 'print Config::CONFIG@<:@"libdir"@:>@') -l$(ruby -r rbconfig -e 'print Config::CONFIG@<:@"RUBY_SO_NAME"@:>@')"
364    RUBY_SITEARCHDIR=`ruby -r rbconfig -e 'print Config::CONFIG@<:@"sitearchdir"@:>@'`
365    RUBY_SITELIBDIR=`ruby -r rbconfig -e 'print Config::CONFIG@<:@"sitelibdir"@:>@'`
366    AC_SUBST(RUBY_CFLAGS)
367    AC_SUBST(RUBY_LIBS)
368    AC_SUBST(RUBY_SITEARCHDIR)
369    AC_SUBST(RUBY_SITELIBDIR)
370    CPPFLAGS="${CPPFLAGS} ${RUBY_CFLAGS}"
371    AC_CHECK_HEADERS([ruby.h],
372     [ac_cv_my_have_ruby="yes"
373      CACA_BINDINGS="${CACA_BINDINGS} Ruby"])
374  fi
375fi
376AM_CONDITIONAL(USE_RUBY, test "${ac_cv_my_have_ruby}" = "yes")
377
378AC_MSG_CHECKING(available language bindings)
379if test -z "${CACA_BINDINGS}"; then
380  AC_MSG_RESULT(no)
381else
382  CACA_BINDINGS="${CACA_BINDINGS# *}"
383  AC_MSG_RESULT([${CACA_BINDINGS}])
384fi
385
386# Build cacaserver?
387ac_cv_my_have_network="no"
388AC_CHECK_HEADERS(sys/socket.h,
389 [ac_cv_my_have_network="yes"])
390AM_CONDITIONAL(USE_NETWORK, test "${ac_cv_my_have_network}" = "yes")
391
392# Use Imlib2?
393if test "${enable_imlib2}" != "no"; then
394  IMLIB2="no"
395  PKG_CHECK_MODULES(IMLIB2, imlib2, [IMLIB2="yes"], [AC_MSG_RESULT(no)])
396  if test "${IMLIB2}" != "no"; then
397    AC_DEFINE(USE_IMLIB2, 1, Define to 1 to use Imlib2)
398  fi
399fi
400
401# Build development tools?
402PANGOFT2="no"
403PKG_CHECK_MODULES(PANGOFT2, pangoft2, [PANGOFT2="yes"], [AC_MSG_RESULT(no)])
404AM_CONDITIONAL(USE_PANGO, test "${PANGOFT2}" != "no")
405
406# Build documentation?
407DOXYGEN="no"
408LATEX="no"
409if test "${enable_doc}" != "no"; then
410  AC_PATH_PROG(DOXYGEN, doxygen, no)
411  if test "${DOXYGEN}" != "no"; then
412    # Build LaTeX documentation?
413    AC_PATH_PROG(LATEX, pdflatex, no)
414    AC_PATH_PROG(KPSEWHICH, kpsewhich, no)
415    AC_PATH_PROG(DVIPS, dvips, no)
416    if test "${DVIPS}" = "no" -o "${KPSEWHICH}" = "no"; then
417      LATEX="no"
418    fi
419    if test "${LATEX}" != "no"; then
420      AC_MSG_CHECKING(for a4.sty and a4wide.sty)
421      if "${KPSEWHICH}" a4.sty >/dev/null 2>&1; then
422        if "${KPSEWHICH}" a4wide.sty >/dev/null 2>&1; then
423          AC_MSG_RESULT(yes)
424        else
425          LATEX="no"
426          AC_MSG_RESULT(no)
427        fi
428      else
429        LATEX="no"
430        AC_MSG_RESULT(no)
431      fi
432    fi
433  fi
434fi
435AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
436AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")
437
438# Use zzuf for fuzzing tests?
439ZZUF="no"
440if test "${enable_zzuf}" != "no"; then
441  AC_PATH_PROG(ZZUF, zzuf, no)
442fi
443AM_CONDITIONAL(USE_ZZUF, test "${ZZUF}" != "no")
444
445AC_CONFIG_FILES([
446  Makefile
447  kernel/Makefile
448  cucul/Makefile
449  caca/Makefile
450  src/Makefile
451  examples/Makefile
452  tests/Makefile
453  tools/Makefile
454  csharp/Makefile
455  cxx/Makefile
456  python/Makefile
457  ruby/Makefile
458  doc/Makefile
459  msvc/Makefile
460])
461AC_CONFIG_FILES([
462  cucul/cucul.pc
463  caca/caca.pc
464  csharp/cucul-sharp.dll.config
465  csharp/caca-sharp.dll.config
466  doc/doxygen.cfg
467])
468AC_CONFIG_FILES([caca-config], [chmod 0755 caca-config])
469AC_OUTPUT
470
Note: See TracBrowser for help on using the repository browser.