source: libcaca/trunk/configure.ac @ 2103

Last change on this file since 2103 was 2103, checked in by Sam Hocevar, 13 years ago
  • Created a tests/ directory for regression tests. Run with "make check".
  • Added a first, simple test program.
  • Property svn:keywords set to Id
File size: 15.3 KB
Line 
1# $Id: configure.ac 2103 2007-11-30 23:48:51Z sam $
2
3AC_INIT(caca/caca.c)
4
5AC_PREREQ(2.50)
6AC_CONFIG_AUX_DIR(autotools)
7AC_CANONICAL_SYSTEM
8
9AM_INIT_AUTOMAKE(libcaca, 0.99.beta13)
10LT_MAJOR="0"
11LT_MINOR="99"
12LT_MICRO="13"
13AC_SUBST(LT_MAJOR)
14AC_SUBST(LT_MINOR)
15AC_SUBST(LT_MICRO)
16LT_VERSION="$LT_MAJOR:$LT_MINOR:$LT_MICRO"
17AC_SUBST(LT_VERSION)
18AM_CONFIG_HEADER(config.h)
19
20AM_PROG_CC_C_O
21AC_PROG_CPP
22AC_PROG_CXX
23AC_PROG_CXXCPP
24_AM_DEPENDENCIES([OBJC])
25OBJC="${CC}"
26AC_SUBST(OBJC)
27AC_SUBST(OBJCFLAGS)
28AM_PROG_AS
29
30AC_LIBTOOL_WIN32_DLL
31AM_PROG_LIBTOOL
32AC_LIBTOOL_CXX
33
34AC_C_CONST
35AC_C_INLINE
36AC_TYPE_SIGNAL
37
38dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
39dnl now otherwise it might be set in an obscure if statement. Same thing for
40dnl PKG_PROG_PKG_CONFIG which needs to be called first.
41AC_EGREP_CPP(yes, foo)
42PKG_PROG_PKG_CONFIG()
43m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
44if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
45  export PKG_CONFIG_LIBDIR=/dev/null
46fi
47
48dnl output driver features
49AC_ARG_ENABLE(slang,
50  [  --enable-slang          slang graphics support (autodetected)])
51AC_ARG_ENABLE(ncurses,
52  [  --enable-ncurses        ncurses graphics support (autodetected)])
53AC_ARG_ENABLE(win32,
54  [  --enable-win32          Windows console support (autodetected)])
55AC_ARG_ENABLE(conio,
56  [  --enable-conio          DOS conio.h graphics support (autodetected)])
57AC_ARG_ENABLE(x11,
58  [  --enable-x11            X11 support (autodetected)])
59AC_ARG_ENABLE(gl,
60  [  --enable-gl             OpenGL support (autodetected)])
61AC_ARG_ENABLE(cocoa,
62  [  --enable-cocoa          Cocoa support (autodetected)])
63AC_ARG_ENABLE(network,
64  [  --enable-network        Network support (autodetected)])
65AC_ARG_ENABLE(vga,
66  [  --enable-vga            VGA support (default disabled)])
67
68dnl language bindings
69AC_ARG_ENABLE(csharp,
70  [  --enable-csharp         C# bindings (autodetected)])
71AC_ARG_ENABLE(cxx,
72  [  --enable-cxx            C++ bindings (autodetected)])
73AC_ARG_ENABLE(ruby,
74  [  --enable-ruby           Ruby bindings (autodetected)])
75
76dnl example programs features
77AC_ARG_ENABLE(imlib2,
78  [  --enable-imlib2         Imlib2 graphics support (autodetected)])
79
80dnl conditional builds
81AC_ARG_ENABLE(debug,
82  [  --enable-debug          build debug versions of the library (default no)])
83AC_ARG_ENABLE(plugins,
84  [  --enable-plugins        make X11 and GL drivers plugins (default disabled)])
85AC_ARG_ENABLE(doc,
86  [  --enable-doc            build documentation (needs doxygen and LaTeX)])
87AC_ARG_ENABLE(zzuf,
88  [  --enable-zzuf           use zzuf for fuzzing tests (autodetected)])
89
90AC_CHECK_HEADERS(stdio.h stdarg.h signal.h sys/ioctl.h sys/time.h inttypes.h endian.h unistd.h arpa/inet.h netinet/in.h winsock2.h errno.h locale.h getopt.h dlfcn.h termios.h)
91AC_CHECK_FUNCS(signal ioctl vsnprintf getenv putenv strcasecmp htons)
92AC_CHECK_FUNCS(usleep gettimeofday)
93
94AC_CHECK_FUNCS(getopt_long,
95 [AC_DEFINE(HAVE_GETOPT_LONG, 1, Define to 1 if you have the `getopt_long' function.)],
96 [AC_CHECK_LIB(gnugetopt, getopt_long,
97   [AC_DEFINE(HAVE_GETOPT_LONG, 1, Define to 1 if you have the `getopt_long' function.)
98    GETOPT_LIBS="${GETOPT_LIBS} -lgnugetopt"])])
99AC_SUBST(GETOPT_LIBS)
100
101AC_MSG_CHECKING(for Sleep)
102AC_TRY_COMPILE([#include <windows.h>],[Sleep(42);],
103 [AC_MSG_RESULT(yes)
104  AC_DEFINE(HAVE_SLEEP, 1, [Define to 1 if you have the `Sleep' function.])],
105 [AC_MSG_RESULT(no)])
106
107AC_MSG_CHECKING(for fsin/fcos)
108AC_TRY_COMPILE([],[asm("fsin\n\tfcos");],
109 [AC_MSG_RESULT(yes)
110  AC_DEFINE(HAVE_FSIN_FCOS, 1, [Define to 1 if you have the `fsin' and `fcos' operands.])],
111 [AC_MSG_RESULT(no)])
112
113AC_MSG_CHECKING(for fldln2/fxch/fyl2x)
114AC_TRY_COMPILE([],[asm("fldln2; fldln2; fxch; fyl2x");],
115 [AC_MSG_RESULT(yes)
116  AC_DEFINE(HAVE_FLDLN2, 1, [Define to 1 if you have the `fldln2' and other floating points operands.])],
117 [AC_MSG_RESULT(no)])
118
119AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
120
121CACA_DRIVERS=""
122
123if test "${enable_conio}" != "no"; then
124  ac_cv_my_have_conio="no"
125  AC_CHECK_HEADERS(conio.h,
126   [AC_MSG_CHECKING(for ScreenUpdate in pc.h)
127    AC_EGREP_HEADER(ScreenUpdate, pc.h,
128     [ac_cv_my_have_conio="yes"
129      AC_MSG_RESULT(yes)
130      AC_DEFINE(SCREENUPDATE_IN_PC_H, 1,
131                Define to 1 if <pc.h> defines ScreenUpdate.)
132      AC_DEFINE(USE_CONIO, 1, Define to 1 to activate the conio.h backend driver)
133      CACA_DRIVERS="${CACA_DRIVERS} conio"],
134     [AC_MSG_RESULT(no)])])
135  if test "${ac_cv_my_have_conio}" = "no" -a "${enable_conio}" = "yes"; then
136    AC_MSG_ERROR([cannot find conio.h])
137  fi
138fi
139
140if test "${enable_win32}" != "no"; then
141  ac_cv_my_have_win32="no"
142  AC_CHECK_HEADERS(windows.h,
143   [AC_MSG_CHECKING(for AllocConsole in windows.h)
144    AC_EGREP_HEADER(AllocConsole, windows.h,
145     [ac_cv_my_have_win32="yes"
146      AC_MSG_RESULT(yes)
147      AC_DEFINE(ALLOCCONSOLE_IN_WINDOWS_H, 1,
148                Define to 1 if <windows.h> defines AllocConsole.)
149      AC_DEFINE(USE_WIN32, 1, Define to 1 to activate the win32 backend driver)
150      CACA_DRIVERS="${CACA_DRIVERS} win32"],
151     [AC_MSG_RESULT(no)])])
152  if test "${ac_cv_my_have_win32}" = "no" -a "${enable_win32}" = "yes"; then
153    AC_MSG_ERROR([cannot find win32 console development files])
154  fi
155fi
156
157if test "${enable_slang}" != "no"; then
158  ac_cv_my_have_slang="no"
159  AC_CHECK_HEADERS(slang.h slang/slang.h,
160   [ac_cv_my_have_slang="yes"
161    AC_DEFINE(USE_SLANG, 1, Define to 1 to activate the slang backend driver)
162    AC_CHECK_LIB(slang, SLsmg_utf8_enable,
163     [AC_DEFINE(HAVE_SLSMG_UTF8_ENABLE, 1, Define to 1 if you have the `SLsmg_utf8_enable' function.)])
164    CPPFLAGS="${CPPFLAGS} -DOPTIMISE_SLANG_PALETTE=1"
165    CACA_LIBS="${CACA_LIBS} -lslang"
166    CACA_DRIVERS="${CACA_DRIVERS} slang"
167    break])
168  if test "${ac_cv_my_have_slang}" = "no" -a "${enable_slang}" = "yes"; then
169    AC_MSG_ERROR([cannot find slang development files])
170  fi
171fi
172
173if test "${enable_x11}" != "no"; then
174  AC_PATH_X
175  AC_CHECK_LIB(X11, XOpenDisplay,
176   [ac_cv_my_have_x11="yes"
177    if test -n "${x_includes}"; then X_CFLAGS="-I${x_includes}"; fi
178    if test -n "${x_libraries}"; then X_LIBS="-L${x_libraries}"; fi
179    AC_DEFINE(USE_X11, 1, Define to 1 to activate the X11 backend driver)
180    CPPFLAGS="${CPPFLAGS} ${X_CFLAGS}"
181    X11_LIBS="${X11_LIBS} -lX11 ${X_LIBS}"
182    CACA_DRIVERS="${CACA_DRIVERS} x11"],
183   [ac_cv_my_have_x11="no"],
184   [[`if test -n "${x_libraries}"; then echo -L${x_libraries}; fi`]])
185  AC_CHECK_HEADERS(X11/XKBlib.h)
186  if test "${ac_cv_my_have_x11}" != "yes" -a "${enable_x11}" = "yes"; then
187    AC_MSG_ERROR([cannot find X11 development files])
188  fi
189fi
190
191if test "${enable_gl}" != "no"; then
192  ac_cv_my_have_gl="no"
193  AC_CHECK_HEADERS(GL/gl.h OpenGL/gl.h,
194   [AC_CHECK_HEADERS(GL/glut.h,
195     [AC_CHECK_LIB(glut, glutCloseFunc,
196       [AC_DEFINE(HAVE_GLUTCLOSEFUNC, 1, Define to 1 if you have the `glutCloseFunc' function.)])
197      AC_CHECK_LIB(glut, glutMainLoopEvent,
198       [ac_cv_my_have_gl="yes"])
199      AC_CHECK_LIB(glut, glutCheckLoop,
200       [ac_cv_my_have_gl="yes"
201        AC_DEFINE(HAVE_GLUTCHECKLOOP, 1, Define to 1 if you have the `glutCheckLoop' function.)])])
202      break])
203  if test "${ac_cv_my_have_gl}" = "yes"; then
204    AC_DEFINE(USE_GL, 1, Define to 1 to activate the OpenGL backend driver)
205    GL_LIBS="${GL_LIBS} -lGL -lglut"
206    CACA_DRIVERS="${CACA_DRIVERS} gl"
207  elif test "${enable_gl}" = "yes"; then
208    AC_MSG_ERROR([cannot find OpenGL+FreeGLUT development files])
209  fi
210fi
211
212if test "${enable_cocoa}" != "no"; then
213  ac_cv_my_have_cocoa="no"
214  AC_CHECK_HEADERS(Cocoa/Cocoa.h,
215   [ac_cv_my_have_cocoa="yes"])
216  if test "${ac_cv_my_have_cocoa}" = "yes"; then
217    case x${target} in
218    xpowerpc*darwin*)
219      # 10.3 needed to link with X11
220      MACOSX_SDK=/Developer/SDKs/MacOSX10.3.9.sdk
221      GCC_VERSION=3.3
222      ARCH="-arch ppc"
223      MACOSX_SDK_CFLAGS="-nostdinc -isystem ${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION} -isystem ${MACOSX_SDK}/usr/include"
224      MACOSX_SDK_CXXFLAGS="-nostdinc++ -I${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION}/c++ -I${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION}/c++/ppc-darwin -I${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION}/c++/backward"
225      MACOSX_SDK_LDFLAGS="-L${MACOSX_SDK}/usr/lib/gcc/darwin -L${MACOSX_SDK}/usr/lib/gcc/darwin/${GCC_VERSION} -L${MACOSX_SDK}/usr/lib"
226      ;;
227    x*86*darwin*)
228      MACOSX_SDK=/Developer/SDKs/MacOSX10.4u.sdk
229      GCC_VERSION=4.0
230      ARCH="-arch i386"
231      MACOSX_SDK_CFLAGS="-isysroot ${MACOSX_SDK}"
232      MACOSX_SDK_CXXFLAGS="${MACOSX_SDK_CFLAGS}"
233      ;;
234    esac
235    CC=gcc-${GCC_VERSION}
236    CXX=g++-${GCC_VERSION}
237    MACOSX_SDK_FRAMEWORKS="-F${MACOSX_SDK}/System/Library/Frameworks"
238    CPPFLAGS="${CPPFLAGS} ${ARCH} ${MACOSX_SDK_FRAMEWORKS}"
239    CFLAGS="${CFLAGS} ${MACOSX_SDK_CFLAGS}"
240    CXXFLAGS="${CXXFLAGS} ${MACOSX_SDK_CXXFLAGS}"
241    OBJCFLAGS="${OBJCFLAGS} ${MACOSX_SDK_CFLAGS}"
242    LDFLAGS="${ARCH} ${MACOSX_SDK_LDFLAGS} ${LDFLAGS}"
243    AC_DEFINE(USE_COCOA, 1, Define to 1 to activate the Cocoa backend driver)
244    CACA_LIBS="${CACA_LIBS} -Wl,-syslibroot,${MACOSX_SDK},-framework,Cocoa"
245    CACA_DRIVERS="${CACA_DRIVERS} cocoa"
246  elif test "${enable_cocoa}" = "yes"; then
247    AC_MSG_ERROR([cannot find Cocoa development files])
248  fi
249fi
250AM_CONDITIONAL(USE_COCOA, test "${ac_cv_my_have_cocoa}" = "yes")
251
252if test "${enable_ncurses}" != "no"; then
253  ac_cv_my_have_ncurses="no"
254  AC_CHECK_HEADERS(ncursesw/ncurses.h ncurses/ncurses.h ncurses.h curses.h,
255   [ncurses="no"
256    AC_CHECK_LIB(ncursesw, initscr,
257     [ncurses="-lncursesw"],
258     [AC_CHECK_LIB(ncurses, initscr,
259       [ncurses="-lncurses"])])
260    if test "${ncurses}" = "no"; then
261      continue
262    fi
263    ac_cv_my_have_ncurses="yes"
264    AC_DEFINE(USE_NCURSES, 1, Define to 1 to activate the ncurses backend driver)
265    CACA_LIBS="${CACA_LIBS} ${ncurses}"
266    CACA_DRIVERS="${CACA_DRIVERS} ncurses"
267    dnl  Check for resizeterm or resize_term
268    SAVED_LIBS="${LIBS}"
269    LIBS="${LIBS} ${ncurses}"
270    AC_CHECK_FUNCS(resizeterm resize_term)
271    LIBS="${SAVED_LIBS}"
272    break])
273  if test "${ac_cv_my_have_ncurses}" = "no" -a "${enable_ncurses}" = "yes"; then
274    AC_MSG_ERROR([cannot find ncurses development files])
275  fi
276fi
277
278if test "${enable_vga}" = "yes"; then
279  ac_cv_my_have_vga="yes"
280  CPPFLAGS="${CPPFLAGS} -I. -D__KERNEL__ -nostdinc -include kernel/kernel.h"
281  CFLAGS="${CFLAGS} -fno-builtin -O2 -Wall"
282  CCASFLAGS="${CCASFLAGS} -I."
283  LDFLAGS="${LDFLAGS} -nostdlib -Wl,-N -Wl,-Ttext -Wl,100000"
284  AC_DEFINE(USE_VGA, 1, Define to 1 to activate the VGA backend driver)
285  CACA_DRIVERS="${CACA_DRIVERS} vga"
286fi
287AM_CONDITIONAL(USE_KERNEL, test "${ac_cv_my_have_vga}" = "yes")
288
289if test "${enable_debug}" = "yes"; then
290  AC_DEFINE(DEBUG, 1, Define to 1 to activate debug)
291fi
292
293if test "${enable_plugins}" = "yes"; then
294  ac_cv_my_have_plugins="yes"
295  AC_DEFINE(USE_PLUGINS, 1, Define to 1 to activate plugins)
296  CACA_LIBS="${CACA_LIBS} -ldl"
297else
298  CACA_LIBS="${CACA_LIBS} ${X11_LIBS} ${GL_LIBS}"
299fi
300AM_CONDITIONAL(USE_PLUGINS, test "${ac_cv_my_have_plugins}" = "yes")
301
302AC_MSG_CHECKING(valid output drivers)
303if test -z "${CACA_DRIVERS}"; then
304  AC_MSG_RESULT(no)
305  AC_MSG_ERROR([no output drivers were selected!])
306else
307  CACA_DRIVERS="${CACA_DRIVERS# *}"
308  AC_MSG_RESULT([${CACA_DRIVERS}])
309fi
310
311AC_SUBST(MATH_LIBS)
312AC_SUBST(GETOPT_LIBS)
313AC_SUBST(CACA_LIBS)
314AC_SUBST(X11_LIBS)
315AC_SUBST(GL_LIBS)
316
317# Optimizations
318CFLAGS="${CFLAGS} -g -O2 -fno-strength-reduce -fomit-frame-pointer"
319# Code qui fait des warnings == code de porc == deux baffes dans ta gueule
320# [Jylam] Removed -Wshadow in order to avoid ncurses/gl conflict
321# (Comme quoi on n'est pas les seuls porcs)
322CFLAGS="${CFLAGS} -Wall -Wpointer-arith -Wcast-align -Wcast-qual -Wstrict-prototypes -Wshadow -Waggregate-return -Wmissing-prototypes -Wnested-externs -Wsign-compare"
323
324CACA_BINDINGS=""
325
326# Build the C++ bindings?
327ac_cv_my_have_cxx="no"
328if test "${enable_cxx}" != "no"; then
329  AC_MSG_CHECKING([working <iostream>])
330  AC_LANG_PUSH(C++)
331  AC_TRY_COMPILE(
332   [#include <iostream>],
333   [],
334   [ac_cv_my_have_cxx="yes"
335    CACA_BINDINGS="${CACA_BINDINGS} C++"])
336  AC_LANG_POP(C++)
337  AC_MSG_RESULT([$ac_cv_my_have_cxx])
338fi
339AM_CONDITIONAL(USE_CXX, test "${ac_cv_my_have_cxx}" = "yes")
340
341# Build the .NET bindings?
342ac_cv_my_have_csharp="no"
343if test "${enable_csharp}" != "no"; then
344  AC_PATH_PROG(GMCS, gmcs, no)
345  AC_PATH_PROG(GACUTIL, gacutil, no)
346  if test "${GMCS}" != "no" -a "${GACUTIL}" != "no"; then
347    ac_cv_my_have_csharp="yes"
348    CACA_BINDINGS="${CACA_BINDINGS} C#"
349  fi
350fi
351AM_CONDITIONAL(USE_CSHARP, test "${ac_cv_my_have_csharp}" = "yes")
352
353# Build the Ruby bindings?
354ac_cv_my_have_ruby="no"
355if test "${enable_ruby}" != "no"; then
356  AC_PATH_PROG(RUBY, ruby, no)
357  if test "${RUBY}" != "no"; then
358    RUBY_CFLAGS="-I$(ruby -r rbconfig -e 'print Config::CONFIG@<:@"archdir"@:>@')"
359    RUBY_LIBS="-L$(ruby -r rbconfig -e 'print Config::CONFIG@<:@"libdir"@:>@') -l$(ruby -r rbconfig -e 'print Config::CONFIG@<:@"RUBY_SO_NAME"@:>@')"
360    RUBY_SITEARCHDIR=`ruby -r rbconfig -e 'print Config::CONFIG@<:@"sitearchdir"@:>@'`
361    RUBY_SITELIBDIR=`ruby -r rbconfig -e 'print Config::CONFIG@<:@"sitelibdir"@:>@'`
362    AC_SUBST(RUBY_CFLAGS)
363    AC_SUBST(RUBY_LIBS)
364    AC_SUBST(RUBY_SITEARCHDIR)
365    AC_SUBST(RUBY_SITELIBDIR)
366    CPPFLAGS="${CPPFLAGS} ${RUBY_CFLAGS}"
367    AC_CHECK_HEADERS([ruby.h],
368     [ac_cv_my_have_ruby="yes"
369      CACA_BINDINGS="${CACA_BINDINGS} Ruby"])
370  fi
371fi
372AM_CONDITIONAL(USE_RUBY, test "${ac_cv_my_have_ruby}" = "yes")
373
374AC_MSG_CHECKING(available language bindings)
375if test -z "${CACA_BINDINGS}"; then
376  AC_MSG_RESULT(no)
377else
378  CACA_BINDINGS="${CACA_BINDINGS# *}"
379  AC_MSG_RESULT([${CACA_BINDINGS}])
380fi
381
382# Build cacaserver?
383ac_cv_my_have_network="no"
384AC_CHECK_HEADERS(sys/socket.h,
385 [ac_cv_my_have_network="yes"])
386AM_CONDITIONAL(USE_NETWORK, test "${ac_cv_my_have_network}" = "yes")
387
388# Use Imlib2?
389if test "${enable_imlib2}" != "no"; then
390  IMLIB2="no"
391  PKG_CHECK_MODULES(IMLIB2, imlib2, [IMLIB2="yes"], [AC_MSG_RESULT(no)])
392  if test "${IMLIB2}" != "no"; then
393    AC_DEFINE(USE_IMLIB2, 1, Define to 1 to use Imlib2)
394  fi
395fi
396
397# Build development tools?
398PANGOFT2="no"
399PKG_CHECK_MODULES(PANGOFT2, pangoft2, [PANGOFT2="yes"], [AC_MSG_RESULT(no)])
400AM_CONDITIONAL(USE_PANGO, test "${PANGOFT2}" != "no")
401
402# Build documentation?
403DOXYGEN="no"
404LATEX="no"
405if test "${enable_doc}" != "no"; then
406  AC_PATH_PROG(DOXYGEN, doxygen, no)
407  if test "${DOXYGEN}" != "no"; then
408    # Build LaTeX documentation?
409    AC_PATH_PROG(LATEX, pdflatex, no)
410    AC_PATH_PROG(KPSEWHICH, kpsewhich, no)
411    AC_PATH_PROG(DVIPS, dvips, no)
412    if test "${DVIPS}" = "no" -o "${KPSEWHICH}" = "no"; then
413      LATEX="no"
414    fi
415    if test "${LATEX}" != "no"; then
416      AC_MSG_CHECKING(for a4.sty and a4wide.sty)
417      if "${KPSEWHICH}" a4.sty >/dev/null 2>&1; then
418        if "${KPSEWHICH}" a4wide.sty >/dev/null 2>&1; then
419          AC_MSG_RESULT(yes)
420        else
421          LATEX="no"
422          AC_MSG_RESULT(no)
423        fi
424      else
425        LATEX="no"
426        AC_MSG_RESULT(no)
427      fi
428    fi
429  fi
430fi
431AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
432AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")
433
434# Use zzuf for fuzzing tests?
435ZZUF="no"
436if test "${enable_zzuf}" != "no"; then
437  AC_PATH_PROG(ZZUF, zzuf, no)
438fi
439AM_CONDITIONAL(USE_ZZUF, test "${ZZUF}" != "no")
440
441AC_CONFIG_FILES([
442  Makefile
443  kernel/Makefile
444  cucul/Makefile
445  caca/Makefile
446  src/Makefile
447  examples/Makefile
448  tests/Makefile
449  tools/Makefile
450  csharp/Makefile
451  cxx/Makefile
452  python/Makefile
453  ruby/Makefile
454  doc/Makefile
455  msvc/Makefile
456])
457AC_CONFIG_FILES([
458  cucul/cucul.pc
459  caca/caca.pc
460  csharp/cucul-sharp.dll.config
461  csharp/caca-sharp.dll.config
462  doc/doxygen.cfg
463])
464AC_CONFIG_FILES([caca-config], [chmod 0755 caca-config])
465AC_OUTPUT
466
Note: See TracBrowser for help on using the repository browser.