source: libcaca/trunk/configure.ac @ 1207

Last change on this file since 1207 was 1207, checked in by Sam Hocevar, 13 years ago
  • Add checks for getopt / getopt_long.
  • Property svn:keywords set to Id
File size: 10.6 KB
Line 
1# $Id: configure.ac 1207 2006-10-19 21:21:00Z sam $
2
3AC_INIT(caca/caca.c)
4
5AC_PREREQ(2.50)
6AC_CONFIG_AUX_DIR(autotools)
7AC_CANONICAL_SYSTEM
8
9AM_INIT_AUTOMAKE(libcaca, 0.99.beta7)
10LT_VERSION="99:0:99"
11AC_SUBST(LT_VERSION)
12AM_CONFIG_HEADER(config.h)
13
14AM_PROG_CC_C_O
15AC_PROG_CPP
16AC_PROG_CXX
17AC_PROG_CXXCPP
18AM_PROG_AS
19
20AC_LIBTOOL_WIN32_DLL
21AM_PROG_LIBTOOL
22AC_LIBTOOL_CXX
23
24AC_C_CONST
25AC_C_INLINE
26AC_TYPE_SIGNAL
27
28dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
29dnl now otherwise it might be set in an obscure if statement. Same thing for
30dnl PKG_PROG_PKG_CONFIG which needs to be called first.
31AC_EGREP_CPP(yes, foo)
32PKG_PROG_PKG_CONFIG()
33m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
34if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
35  export PKG_CONFIG_LIBDIR=/dev/null
36fi
37
38dnl output driver features
39AC_ARG_ENABLE(slang,
40  [  --enable-slang          slang graphics support (autodetected)])
41AC_ARG_ENABLE(ncurses,
42  [  --enable-ncurses        ncurses graphics support (autodetected)])
43AC_ARG_ENABLE(win32,
44  [  --enable-win32          Windows console support (autodetected)])
45AC_ARG_ENABLE(conio,
46  [  --enable-conio          DOS conio.h graphics support (autodetected)])
47AC_ARG_ENABLE(x11,
48  [  --enable-x11            X11 support (autodetected)])
49AC_ARG_ENABLE(gl,
50  [  --enable-gl             OpenGL support (autodetected)])
51AC_ARG_ENABLE(network,
52  [  --enable-network        Network support (autodetected)])
53AC_ARG_ENABLE(vga,
54  [  --enable-vga            VGA support (default disabled)])
55
56dnl language bindings
57AC_ARG_ENABLE(cxx,
58  [  --enable-cxx            C++ bindings (default disabled)])
59
60dnl example programs features
61AC_ARG_ENABLE(imlib2,
62  [  --enable-imlib2         Imlib2 graphics support (default enabled)])
63
64dnl conditional builds
65AC_ARG_ENABLE(doc,
66  [  --enable-doc            build documentation (needs doxygen and LaTeX)])
67
68AC_CHECK_HEADERS(stdio.h stdarg.h signal.h sys/ioctl.h sys/time.h inttypes.h endian.h unistd.h arpa/inet.h netinet/in.h winsock2.h errno.h locale.h getopt.h)
69AC_CHECK_FUNCS(signal ioctl vsnprintf getenv putenv strcasecmp htons)
70AC_CHECK_FUNCS(usleep gettimeofday)
71
72AC_CHECK_FUNCS(getopt_long,
73 [AC_DEFINE(HAVE_GETOPT_LONG, 1, Define to 1 if you have the `getopt_long' function.)],
74 [AC_CHECK_LIB(gnugetopt, getopt_long,
75   [AC_DEFINE(HAVE_GETOPT_LONG, 1, Define to 1 if you have the `getopt_long' function.)
76    GETOPT_LIBS="${GETOPT_LIBS} -lgnugetopt"])])
77AC_SUBST(GETOPT_LIBS)
78
79AC_MSG_CHECKING(for Sleep)
80AC_TRY_COMPILE([#include <windows.h>],[Sleep(42);],
81 [AC_MSG_RESULT(yes)
82  AC_DEFINE(HAVE_SLEEP, 1, [Define to 1 if you have the `Sleep' function.])],
83 [AC_MSG_RESULT(no)])
84
85AC_MSG_CHECKING(for fsin/fcos)
86AC_TRY_COMPILE([],[asm("fsin\n\tfcos");],
87 [AC_MSG_RESULT(yes)
88  AC_DEFINE(HAVE_FSIN_FCOS, 1, [Define to 1 if you have the `fsin' and `fcos' operands.])],
89 [AC_MSG_RESULT(no)])
90
91AC_MSG_CHECKING(for fldln2/fxch/fyl2x)
92AC_TRY_COMPILE([],[asm("fldln2; fldln2; fxch; fyl2x");],
93 [AC_MSG_RESULT(yes)
94  AC_DEFINE(HAVE_FLDLN2, 1, [Define to 1 if you have the `fldln2' and other floating points operands.])],
95 [AC_MSG_RESULT(no)])
96
97AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
98
99CACA_DRIVERS=""
100
101if test "${enable_conio}" != "no"; then
102  ac_cv_my_have_conio="no"
103  AC_CHECK_HEADERS(conio.h,
104   [AC_MSG_CHECKING(for ScreenUpdate in pc.h)
105    AC_EGREP_HEADER(ScreenUpdate, pc.h,
106     [ac_cv_my_have_conio="yes"
107      AC_MSG_RESULT(yes)
108      AC_DEFINE(SCREENUPDATE_IN_PC_H, 1,
109                Define to 1 if <pc.h> defines ScreenUpdate.)
110      AC_DEFINE(USE_CONIO, 1, Define to 1 to activate the conio.h backend driver)
111      CACA_DRIVERS="${CACA_DRIVERS} conio"],
112     [AC_MSG_RESULT(no)])])
113  if test "${ac_cv_my_have_conio}" = "no" -a "${enable_conio}" = "yes"; then
114    AC_MSG_ERROR([cannot find conio.h])
115  fi
116fi
117
118if test "${enable_win32}" != "no"; then
119  ac_cv_my_have_win32="no"
120  AC_CHECK_HEADERS(windows.h,
121   [AC_MSG_CHECKING(for AllocConsole in windows.h)
122    AC_EGREP_HEADER(AllocConsole, windows.h,
123     [ac_cv_my_have_win32="yes"
124      AC_MSG_RESULT(yes)
125      AC_DEFINE(ALLOCCONSOLE_IN_WINDOWS_H, 1,
126                Define to 1 if <windows.h> defines AllocConsole.)
127      AC_DEFINE(USE_WIN32, 1, Define to 1 to activate the win32 backend driver)
128      CACA_DRIVERS="${CACA_DRIVERS} win32"],
129     [AC_MSG_RESULT(no)])])
130  if test "${ac_cv_my_have_win32}" = "no" -a "${enable_win32}" = "yes"; then
131    AC_MSG_ERROR([cannot find win32 console development files])
132  fi
133fi
134
135if test "${enable_slang}" != "no"; then
136  ac_cv_my_have_slang="no"
137  AC_CHECK_HEADERS(slang.h slang/slang.h,
138   [ac_cv_my_have_slang="yes"
139    AC_DEFINE(USE_SLANG, 1, Define to 1 to activate the slang backend driver)
140    AC_CHECK_LIB(slang, SLsmg_utf8_enable,
141     [AC_DEFINE(HAVE_SLSMG_UTF8_ENABLE, 1, Define to 1 if you have the `SLsmg_utf8_enable' function.)])
142    CPPFLAGS="${CPPFLAGS} -DOPTIMISE_SLANG_PALETTE=1"
143    CACA_LIBS="${CACA_LIBS} -lslang"
144    CACA_DRIVERS="${CACA_DRIVERS} slang"
145    break])
146  if test "${ac_cv_my_have_slang}" = "no" -a "${enable_slang}" = "yes"; then
147    AC_MSG_ERROR([cannot find slang development files])
148  fi
149fi
150
151if test "${enable_x11}" != "no"; then
152  AC_PATH_X
153  AC_CHECK_LIB(X11, XOpenDisplay,
154   [ac_cv_my_have_x11="yes"
155    if test -n "${x_includes}"; then X_CFLAGS="-I${x_includes}"; fi
156    if test -n "${x_libraries}"; then X_LIBS="-L${x_libraries}"; fi
157    AC_DEFINE(USE_X11, 1, Define to 1 to activate the X11 backend driver)
158    CPPFLAGS="${CPPFLAGS} ${X_CFLAGS}"
159    CACA_LIBS="${CACA_LIBS} -lX11 ${X_LIBS}"
160    CACA_DRIVERS="${CACA_DRIVERS} x11"],
161   [ac_cv_my_have_x11="no"],
162   [[`if test -n "${x_libraries}"; then echo -L${x_libraries}; fi`]])
163  AC_CHECK_HEADERS(X11/XKBlib.h)
164  if test "${ac_cv_my_have_x11}" != "yes" -a "${enable_x11}" = "yes"; then
165    AC_MSG_ERROR([cannot find X11 development files])
166  fi
167fi
168
169if test "${enable_gl}" != "no"; then
170  ac_cv_my_have_gl="no"
171  AC_CHECK_HEADERS(GL/gl.h OpenGL/gl.h,
172   [AC_CHECK_HEADERS(GL/glut.h,
173     [AC_CHECK_LIB(glut, glutCloseFunc,
174       [AC_DEFINE(HAVE_GLUTCLOSEFUNC, 1, Define to 1 if you have the `glutCloseFunc' function.)])
175      AC_CHECK_LIB(glut, glutMainLoopEvent,
176       [ac_cv_my_have_gl="yes"])
177      AC_CHECK_LIB(glut, glutCheckLoop,
178       [ac_cv_my_have_gl="yes"
179        AC_DEFINE(HAVE_GLUTCHECKLOOP, 1, Define to 1 if you have the `glutCheckLoop' function.)])])
180      break])
181  if test "${ac_cv_my_have_gl}" = "yes"; then
182    AC_DEFINE(USE_GL, 1, Define to 1 to activate the OpenGL backend driver)
183    CACA_LIBS="${CACA_LIBS} -lGL -lglut"
184    CACA_DRIVERS="${CACA_DRIVERS} gl"
185  elif test "${enable_gl}" = "yes"; then
186    AC_MSG_ERROR([cannot find OpenGL+FreeGLUT development files])
187  fi
188fi
189
190if test "${enable_ncurses}" != "no"; then
191  ac_cv_my_have_ncurses="no"
192  AC_CHECK_HEADERS(ncursesw/ncurses.h ncurses/ncurses.h ncurses.h curses.h,
193   [ncurses="no"
194    AC_CHECK_LIB(ncursesw, initscr,
195     [ncurses="-lncursesw"],
196     [AC_CHECK_LIB(ncurses, initscr,
197       [ncurses="-lncurses"])])
198    if test "${ncurses}" = "no"; then
199      continue
200    fi
201    ac_cv_my_have_ncurses="yes"
202    AC_DEFINE(USE_NCURSES, 1, Define to 1 to activate the ncurses backend driver)
203    CACA_LIBS="${CACA_LIBS} ${ncurses}"
204    CACA_DRIVERS="${CACA_DRIVERS} ncurses"
205    dnl  Check for resizeterm or resize_term
206    SAVED_LIBS="${LIBS}"
207    LIBS="${LIBS} ${ncurses}"
208    AC_CHECK_FUNCS(resizeterm resize_term)
209    LIBS="${SAVED_LIBS}"
210    break])
211  if test "${ac_cv_my_have_ncurses}" = "no" -a "${enable_ncurses}" = "yes"; then
212    AC_MSG_ERROR([cannot find ncurses development files])
213  fi
214fi
215
216if test "${enable_vga}" = "yes"; then
217  ac_cv_my_have_vga="yes"
218  CPPFLAGS="${CPPFLAGS} -I. -D__KERNEL__ -nostdinc -include kernel/kernel.h"
219  CFLAGS="${CFLAGS} -fno-builtin -O2 -Wall"
220  CCASFLAGS="${CCASFLAGS} -I."
221  LDFLAGS="${LDFLAGS} -nostdlib -Wl,-N -Wl,-Ttext -Wl,100000"
222  AC_DEFINE(USE_VGA, 1, Define to 1 to activate the VGA backend driver)
223  CACA_DRIVERS="${CACA_DRIVERS} vga"
224fi
225AM_CONDITIONAL(USE_KERNEL, test "${ac_cv_my_have_vga}" = "yes")
226
227AC_MSG_CHECKING(valid output drivers)
228if test -z "${CACA_DRIVERS}"; then
229  AC_MSG_RESULT(no)
230  AC_MSG_ERROR([no output drivers were selected!])
231else
232  CACA_DRIVERS="${CACA_DRIVERS# *}"
233  AC_MSG_RESULT([${CACA_DRIVERS}])
234fi
235
236
237AC_SUBST(MATH_LIBS)
238AC_SUBST(GETOPT_LIBS)
239AC_SUBST(CACA_LIBS)
240
241# Optimizations
242CFLAGS="${CFLAGS} -g -O2 -fno-strength-reduce -fomit-frame-pointer"
243# Code qui fait des warnings == code de porc == deux baffes dans ta gueule
244# [Jylam] Removed -Wshadow in order to avoid ncurses/gl conflict
245# (Comme quoi on est pas les seuls porcs)
246CFLAGS="${CFLAGS} -Wall -Wpointer-arith -Wcast-align -Wcast-qual -Wstrict-prototypes -Waggregate-return -Wmissing-prototypes -Wnested-externs -Wsign-compare"
247
248# Build the C++ bindings?
249ac_cv_my_have_cxx="no"
250if test "${enable_cxx}" = "yes"; then
251  ac_cv_my_have_cxx="yes"
252fi
253AM_CONDITIONAL(USE_CXX, test "${ac_cv_my_have_cxx}" = "yes")
254
255# Build cacaserver?
256ac_cv_my_have_network="no"
257AC_CHECK_HEADERS(sys/socket.h,
258 [ac_cv_my_have_network="yes"])
259AM_CONDITIONAL(USE_NETWORK, test "${ac_cv_my_have_network}" = "yes")
260
261# Use Imlib2?
262if test "${enable_imlib2}" != "no"; then
263  IMLIB2="no"
264  PKG_CHECK_MODULES(imlib2, imlib2, [IMLIB2="yes"], [AC_MSG_RESULT(no)])
265  if test "${IMLIB2}" = no; then
266    AC_MSG_ERROR([[cannot find Imlib2 development files. Without Imlib2, cacaview will only open BMP files; if this is really what you want, re-run configure with '--disable-imlib2'.]])
267  fi
268fi
269
270# Build development tools?
271PANGOFT2="no"
272PKG_CHECK_MODULES(pangoft2, pangoft2, [PANGOFT2="yes"], [AC_MSG_RESULT(no)])
273AM_CONDITIONAL(USE_PANGO, test "${PANGOFT2}" != "no")
274
275# Build documentation?
276DOXYGEN="no"
277LATEX="no"
278if test "${enable_doc}" != "no"; then
279  AC_PATH_PROG(DOXYGEN, doxygen, no)
280  if test "${DOXYGEN}" = "no"; then
281    AC_MSG_ERROR([[cannot find doxygen, which is needed to build the libcaca documentation; if this is really what you want, re-run configure with '--disable-doc'.]])
282  fi
283
284  # Build LaTeX documentation?
285  AC_PATH_PROG(LATEX, pdflatex, no)
286  AC_PATH_PROG(DVIPS, dvips, no)
287  if test "${DVIPS}" = "no"; then
288    LATEX="no"
289  fi
290  AC_MSG_CHECKING(for a4wide.sty)
291  if test -f /usr/share/texmf/tex/latex/misc/a4wide.sty; then
292    AC_MSG_RESULT(yes)
293  elif test -f /usr/share/texmf-tetex/tex/latex/a4wide/a4wide.sty; then
294    AC_MSG_RESULT(yes)
295  else
296    LATEX="no"
297    AC_MSG_RESULT(no)
298  fi
299fi
300AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
301AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")
302
303AC_CONFIG_FILES([
304  Makefile
305  kernel/Makefile
306  cucul/Makefile
307  caca/Makefile
308  src/Makefile
309  test/Makefile
310  tools/Makefile
311  cxx/Makefile
312  doc/Makefile
313  autotools/Makefile
314  msvc/Makefile
315])
316AC_CONFIG_FILES([
317  cucul/cucul.pc
318  caca/caca.pc
319  doc/doxygen.cfg
320])
321AC_CONFIG_FILES([caca-config], [chmod 0755 caca-config])
322AC_OUTPUT
323
Note: See TracBrowser for help on using the repository browser.