source: libcaca/trunk/configure.ac @ 1074

Last change on this file since 1074 was 1074, checked in by Sam Hocevar, 14 years ago
  • Check for <getopt.h> and getopt_long.
  • Property svn:keywords set to Id
File size: 10.8 KB
Line 
1# $Id: configure.ac 1074 2006-09-21 16:59:23Z sam $
2
3AC_INIT(caca/caca.c)
4
5AC_PREREQ(2.50)
6AC_CONFIG_AUX_DIR(autotools)
7AC_CANONICAL_SYSTEM
8
9AM_INIT_AUTOMAKE(libcaca, 0.99.beta4)
10LT_VERSION="99:0:99"
11AC_SUBST(LT_VERSION)
12AM_CONFIG_HEADER(config.h)
13
14AM_PROG_CC_C_O
15AC_PROG_CPP
16AC_PROG_CXX
17AC_PROG_CXXCPP
18AM_PROG_AS
19
20AC_LIBTOOL_WIN32_DLL
21AM_PROG_LIBTOOL
22AC_LIBTOOL_CXX
23
24AC_C_CONST
25AC_C_INLINE
26AC_TYPE_SIGNAL
27
28dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
29dnl now otherwise it might be set in an obscure if statement. Same thing for
30dnl PKG_PROG_PKG_CONFIG which needs to be called first.
31AC_EGREP_CPP(yes, foo)
32PKG_PROG_PKG_CONFIG()
33m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
34if test "$build" != "$host" -a "${PKG_CONFIG_LIBDIR}" = ""; then
35  export PKG_CONFIG_LIBDIR=/dev/null
36fi
37
38dnl output driver features
39AC_ARG_ENABLE(slang,
40  [  --enable-slang          slang graphics support (autodetected)])
41AC_ARG_ENABLE(ncurses,
42  [  --enable-ncurses        ncurses graphics support (autodetected)])
43AC_ARG_ENABLE(win32,
44  [  --enable-win32          Windows console support (autodetected)])
45AC_ARG_ENABLE(conio,
46  [  --enable-conio          DOS conio.h graphics support (autodetected)])
47AC_ARG_ENABLE(x11,
48  [  --enable-x11            X11 support (autodetected)])
49AC_ARG_ENABLE(gl,
50  [  --enable-gl             OpenGL support (autodetected)])
51AC_ARG_ENABLE(network,
52  [  --enable-network        Network support (autodetected)])
53AC_ARG_ENABLE(vga,
54  [  --enable-vga            VGA support (default disabled)])
55
56dnl language bindings
57AC_ARG_ENABLE(cxx,
58  [  --enable-cxx            C++ bindings (default disabled)])
59
60dnl example programs features
61AC_ARG_ENABLE(imlib2,
62  [  --enable-imlib2         Imlib2 graphics support (default enabled)])
63
64dnl conditional builds
65AC_ARG_ENABLE(doc,
66  [  --enable-doc            build documentation (needs doxygen and LaTeX)])
67
68AC_CHECK_HEADERS(stdio.h stdarg.h signal.h sys/ioctl.h sys/time.h inttypes.h endian.h unistd.h arpa/inet.h netinet/in.h winsock2.h errno.h locale.h getopt.h)
69AC_CHECK_FUNCS(signal ioctl vsnprintf getenv putenv strcasecmp htons)
70AC_CHECK_FUNCS(usleep gettimeofday getopt_long)
71
72AC_MSG_CHECKING(for Sleep)
73AC_TRY_COMPILE([#include <windows.h>],[Sleep(42);],
74 [AC_MSG_RESULT(yes)
75  AC_DEFINE(HAVE_SLEEP, 1, [Define to 1 if you have the `Sleep' function.])],
76 [AC_MSG_RESULT(no)])
77
78AC_MSG_CHECKING(for fsin/fcos)
79AC_TRY_COMPILE([],[asm("fsin\n\tfcos");],
80 [AC_MSG_RESULT(yes)
81  AC_DEFINE(HAVE_FSIN_FCOS, 1, [Define to 1 if you have the `fsin' and `fcos' operands.])],
82 [AC_MSG_RESULT(no)])
83
84AC_MSG_CHECKING(for fldln2/fxch/fyl2x)
85AC_TRY_COMPILE([],[asm("fldln2; fldln2; fxch; fyl2x");],
86 [AC_MSG_RESULT(yes)
87  AC_DEFINE(HAVE_FLDLN2, 1, [Define to 1 if you have the `fldln2' and other floating points operands.])],
88 [AC_MSG_RESULT(no)])
89
90AC_CHECK_FUNCS(getopt_long,
91 [AC_DEFINE(HAVE_GETOPT_LONG, 1, Define to 1 if you have the `getopt_long' function.)],
92 [AC_CHECK_LIB(gnugetopt, getopt_long,
93   [AC_DEFINE(HAVE_GETOPT_LONG, 1, Define to 1 if you have the `getopt_long' function.)
94    GETOPT_LIBS="${GETOPT_LIBS} -lgnugetopt"])])
95
96AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
97
98CACA_DRIVERS=""
99
100if test "${enable_conio}" != "no"; then
101  ac_cv_my_have_conio="no"
102  AC_CHECK_HEADERS(conio.h,
103   [AC_MSG_CHECKING(for ScreenUpdate in pc.h)
104    AC_EGREP_HEADER(ScreenUpdate, pc.h,
105     [ac_cv_my_have_conio="yes"
106      AC_MSG_RESULT(yes)
107      AC_DEFINE(SCREENUPDATE_IN_PC_H, 1,
108                Define to 1 if <pc.h> defines ScreenUpdate.)
109      AC_DEFINE(USE_CONIO, 1, Define to 1 to activate the conio.h backend driver)
110      CACA_DRIVERS="${CACA_DRIVERS} conio"],
111     [AC_MSG_RESULT(no)])])
112  if test "${ac_cv_my_have_conio}" = "no" -a "${enable_conio}" = "yes"; then
113    AC_MSG_ERROR([cannot find conio.h])
114  fi
115fi
116
117if test "${enable_win32}" != "no"; then
118  ac_cv_my_have_win32="no"
119  AC_CHECK_HEADERS(windows.h,
120   [AC_MSG_CHECKING(for AllocConsole in windows.h)
121    AC_EGREP_HEADER(AllocConsole, windows.h,
122     [ac_cv_my_have_win32="yes"
123      AC_MSG_RESULT(yes)
124      AC_DEFINE(ALLOCCONSOLE_IN_WINDOWS_H, 1,
125                Define to 1 if <windows.h> defines AllocConsole.)
126      AC_DEFINE(USE_WIN32, 1, Define to 1 to activate the win32 backend driver)
127      CACA_DRIVERS="${CACA_DRIVERS} win32"],
128     [AC_MSG_RESULT(no)])])
129  if test "${ac_cv_my_have_win32}" = "no" -a "${enable_win32}" = "yes"; then
130    AC_MSG_ERROR([cannot find win32 console development files])
131  fi
132fi
133
134if test "${enable_slang}" != "no"; then
135  ac_cv_my_have_slang="no"
136  AC_CHECK_HEADERS(slang.h slang/slang.h,
137   [ac_cv_my_have_slang="yes"
138    AC_DEFINE(USE_SLANG, 1, Define to 1 to activate the slang backend driver)
139    AC_CHECK_LIB(slang, SLsmg_utf8_enable,
140     [AC_DEFINE(HAVE_SLSMG_UTF8_ENABLE, 1, Define to 1 if you have the `SLsmg_utf8_enable' function.)])
141    CPPFLAGS="${CPPFLAGS} -DOPTIMISE_SLANG_PALETTE=1"
142    CACA_LIBS="${CACA_LIBS} -lslang"
143    CACA_DRIVERS="${CACA_DRIVERS} slang"
144    break])
145  if test "${ac_cv_my_have_slang}" = "no" -a "${enable_slang}" = "yes"; then
146    AC_MSG_ERROR([cannot find slang development files])
147  fi
148fi
149
150if test "${enable_x11}" != "no"; then
151  AC_PATH_X
152  AC_CHECK_LIB(X11, XOpenDisplay,
153   [ac_cv_my_have_x11="yes"
154    if test -n "${x_includes}"; then X_CFLAGS="-I${x_includes}"; fi
155    if test -n "${x_libraries}"; then X_LIBS="-L${x_libraries}"; fi
156    AC_DEFINE(USE_X11, 1, Define to 1 to activate the X11 backend driver)
157    CPPFLAGS="${CPPFLAGS} ${X_CFLAGS}"
158    CACA_LIBS="${CACA_LIBS} -lX11 ${X_LIBS}"
159    CACA_DRIVERS="${CACA_DRIVERS} x11"],
160   [ac_cv_my_have_x11="no"],
161   [[`if test -n "${x_libraries}"; then echo -L${x_libraries}; fi`]])
162  AC_CHECK_HEADERS(X11/XKBlib.h)
163  if test "${ac_cv_my_have_x11}" != "yes" -a "${enable_x11}" = "yes"; then
164    AC_MSG_ERROR([cannot find X11 development files])
165  fi
166fi
167
168if test "${enable_gl}" != "no"; then
169  ac_cv_my_have_gl="no"
170  AC_CHECK_HEADERS(GL/gl.h OpenGL/gl.h,
171   [AC_CHECK_HEADERS(GL/glut.h,
172     [AC_CHECK_LIB(glut, glutCloseFunc,
173       [AC_DEFINE(HAVE_GLUTCLOSEFUNC, 1, Define to 1 if you have the `glutCloseFunc' function.)])
174      AC_CHECK_LIB(glut, glutMainLoopEvent,
175       [ac_cv_my_have_gl="yes"])
176      AC_CHECK_LIB(glut, glutCheckLoop,
177       [ac_cv_my_have_gl="yes"
178        AC_DEFINE(HAVE_GLUTCHECKLOOP, 1, Define to 1 if you have the `glutCheckLoop' function.)])])
179      break])
180  if test "${ac_cv_my_have_gl}" = "yes"; then
181    AC_DEFINE(USE_GL, 1, Define to 1 to activate the OpenGL backend driver)
182    CACA_LIBS="${CACA_LIBS} -lGL -lglut"
183    CACA_DRIVERS="${CACA_DRIVERS} gl"
184  elif test "${enable_gl}" = "yes"; then
185    AC_MSG_ERROR([cannot find OpenGL+FreeGLUT development files])
186  fi
187fi
188
189if test "${enable_ncurses}" != "no"; then
190  ac_cv_my_have_ncurses="no"
191  AC_CHECK_HEADERS(ncursesw/ncurses.h ncurses/ncurses.h ncurses.h curses.h,
192   [ncurses="no"
193    AC_CHECK_LIB(ncursesw, initscr,
194     [ncurses="-lncursesw"],
195     [AC_CHECK_LIB(ncurses, initscr,
196       [ncurses="-lncurses"])])
197    if test "${ncurses}" = "no"; then
198      continue
199    fi
200    ac_cv_my_have_ncurses="yes"
201    AC_DEFINE(USE_NCURSES, 1, Define to 1 to activate the ncurses backend driver)
202    CACA_LIBS="${CACA_LIBS} ${ncurses}"
203    CACA_DRIVERS="${CACA_DRIVERS} ncurses"
204    dnl  Check for resizeterm or resize_term
205    SAVED_LIBS="${LIBS}"
206    LIBS="${LIBS} ${ncurses}"
207    AC_CHECK_FUNCS(resizeterm resize_term)
208    LIBS="${SAVED_LIBS}"
209    break])
210  if test "${ac_cv_my_have_ncurses}" = "no" -a "${enable_ncurses}" = "yes"; then
211    AC_MSG_ERROR([cannot find ncurses development files])
212  fi
213fi
214
215if test "${enable_vga}" = "yes"; then
216  ac_cv_my_have_vga="yes"
217  CPPFLAGS="${CPPFLAGS} -I. -D__KERNEL__ -nostdinc -include kernel/kernel.h"
218  CFLAGS="${CFLAGS} -fno-builtin -O2 -Wall"
219  CCASFLAGS="${CCASFLAGS} -I."
220  LDFLAGS="${LDFLAGS} -nostdlib -Wl,-N -Wl,-Ttext -Wl,100000"
221  AC_DEFINE(USE_VGA, 1, Define to 1 to activate the VGA backend driver)
222  CACA_DRIVERS="${CACA_DRIVERS} vga"
223fi
224AM_CONDITIONAL(USE_KERNEL, test "${ac_cv_my_have_vga}" = "yes")
225
226AC_MSG_CHECKING(valid output drivers)
227if test -z "${CACA_DRIVERS}"; then
228  AC_MSG_RESULT(no)
229  AC_MSG_ERROR([no output drivers were selected!])
230else
231  AC_MSG_RESULT([${CACA_DRIVERS}])
232fi
233
234
235AC_SUBST(MATH_LIBS)
236AC_SUBST(GETOPT_LIBS)
237AC_SUBST(CACA_LIBS)
238
239# Optimizations
240CFLAGS="${CFLAGS} -g -O2 -fno-strength-reduce -fomit-frame-pointer"
241# Code qui fait des warnings == code de porc == deux baffes dans ta gueule
242# [Jylam] Removed -Wshadow in order to avoid ncurses/gl conflict
243# (Comme quoi on est pas les seuls porcs)
244CFLAGS="${CFLAGS} -Wall -Wpointer-arith -Wcast-align -Wcast-qual -Wstrict-prototypes -Waggregate-return -Wmissing-prototypes -Wnested-externs -Wsign-compare"
245
246# Build the C++ bindings?
247ac_cv_my_have_cxx="no"
248if test "${enable_cxx}" = "yes"; then
249  ac_cv_my_have_cxx="yes"
250fi
251AM_CONDITIONAL(USE_CXX, test "${ac_cv_my_have_cxx}" = "yes")
252
253# Build cacaserver?
254ac_cv_my_have_network="no"
255AC_CHECK_HEADERS(sys/socket.h,
256 [ac_cv_my_have_network="yes"])
257AM_CONDITIONAL(USE_NETWORK, test "${ac_cv_my_have_network}" = "yes")
258
259# Use Imlib2?
260ac_cv_my_have_imlib2="no"
261save_CPPFLAGS="${CPPFLAGS}"
262if test "${enable_imlib2}" != "no"; then
263  AC_PATH_PROG(IMLIB2_CONFIG, imlib2-config, no)
264  if test "${IMLIB2_CONFIG}" != "no"; then
265    CPPFLAGS="${CPPFLAGS} `imlib2-config --cflags` -DX_DISPLAY_MISSING=1"
266  fi
267  AC_CHECK_HEADERS(Imlib2.h,
268    ac_cv_my_have_imlib2="yes",
269   [ac_cv_my_have_imlib2="no"
270    AC_MSG_ERROR([[cannot find Imlib2 development files. Without Imlib2, cacaview will only open BMP files; if this is really what you want, re-run configure with '--disable-imlib2'.]])])
271  CPPFLAGS="${save_CPPFLAGS}"
272fi
273AM_CONDITIONAL(USE_IMLIB2, test "${ac_cv_my_have_imlib2}" = "yes")
274
275# Build development tools?
276PANGOFT2="no"
277PKG_CHECK_MODULES(pangoft2, pangoft2, [PANGOFT2="yes"], [AC_MSG_RESULT(no)])
278AM_CONDITIONAL(USE_PANGO, test "${PANGOFT2}" != "no")
279
280# Build documentation?
281DOXYGEN="no"
282LATEX="no"
283if test "${enable_doc}" != "no"; then
284  AC_PATH_PROG(DOXYGEN, doxygen, no)
285  if test "${DOXYGEN}" = "no"; then
286    AC_MSG_ERROR([[cannot find doxygen, which is needed to build the libcaca documentation; if this is really what you want, re-run configure with '--disable-doc'.]])
287  fi
288
289  # Build LaTeX documentation?
290  AC_PATH_PROG(LATEX, pdflatex, no)
291  AC_PATH_PROG(DVIPS, dvips, no)
292  if test "${DVIPS}" = "no"; then
293    LATEX="no"
294  fi
295  AC_MSG_CHECKING(for a4wide.sty)
296  if test -f /usr/share/texmf/tex/latex/misc/a4wide.sty; then
297    AC_MSG_RESULT(yes)
298  elif test -f /usr/share/texmf-tetex/tex/latex/a4wide/a4wide.sty; then
299    AC_MSG_RESULT(yes)
300  else
301    LATEX="no"
302    AC_MSG_RESULT(no)
303  fi
304fi
305AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
306AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")
307
308AC_CONFIG_FILES([
309  Makefile
310  kernel/Makefile
311  cucul/Makefile
312  caca/Makefile
313  src/Makefile
314  test/Makefile
315  tools/Makefile
316  cxx/Makefile
317  doc/Makefile
318  autotools/Makefile
319  msvc/Makefile
320])
321AC_CONFIG_FILES([
322  cucul/cucul.pc
323  caca/caca.pc
324  doc/doxygen.cfg
325])
326AC_CONFIG_FILES([caca-config], [chmod 0755 caca-config])
327AC_OUTPUT
328
Note: See TracBrowser for help on using the repository browser.